| 1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162 |
- /*
- Copyright Oliver Kowalke 2009.
- Distributed under the Boost Software License, Version 1.0.
- (See accompanying file LICENSE_1_0.txt or copy at
- http://www.boost.org/LICENSE_1_0.txt)
- */
- /****************************************************************************************
- * *
- * ---------------------------------------------------------------------------------- *
- * | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | *
- * ---------------------------------------------------------------------------------- *
- * | 0x0 | 0x4 | 0x8 | 0xc | 0x10 | 0x14 | 0x18 | 0x1c | *
- * ---------------------------------------------------------------------------------- *
- * | R12 | R13 | R14 | R15 | *
- * ---------------------------------------------------------------------------------- *
- * ---------------------------------------------------------------------------------- *
- * | 8 | 9 | 10 | 11 | 12 | 13 | 14 | 15 | *
- * ---------------------------------------------------------------------------------- *
- * | 0x20 | 0x24 | 0x28 | 0x2c | 0x30 | 0x34 | 0x38 | 0x3c | *
- * ---------------------------------------------------------------------------------- *
- * | RBX | RBP | RIP | EXIT | *
- * ---------------------------------------------------------------------------------- *
- * *
- ****************************************************************************************/
- .text
- .globl make_fcontext
- .type make_fcontext,@function
- .align 16
- make_fcontext:
- /* first arg of make_fcontext() == top of context-stack */
- movq %rdi, %rax
- /* shift address in RAX to lower 16 byte boundary */
- andq $-16, %rax
- /* reserve space for context-data on context-stack */
- /* on context-function entry: (RSP -0x8) % 16 == 0 */
- leaq -0x40(%rax), %rax
- /* third arg of make_fcontext() == address of context-function */
- movq %rdx, 0x30(%rax)
- /* compute abs address of label finish */
- leaq finish(%rip), %rcx
- /* save address of finish as return-address for context-function */
- /* will be entered after context-function returns */
- movq %rcx, 0x38(%rax)
- ret /* return pointer to context-data */
- finish:
- /* exit code is zero */
- xorq %rdi, %rdi
- /* exit application */
- call _exit@PLT
- hlt
- .size make_fcontext,.-make_fcontext
- /* Mark that we don't need executable stack. */
- .section .note.GNU-stack,"",%progbits
|
