| 12345678910111213141516171819202122232425262728293031323334 |
- dnl @synopsis AC_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])
- dnl
- dnl This macro sets VARNAME to the expansion of the DIR variable,
- dnl taking care of fixing up ${prefix} and such.
- dnl
- dnl VARNAME is then offered as both an output variable and a C
- dnl preprocessor symbol.
- dnl
- dnl Example:
- dnl
- dnl AC_DEFINE_DIR([DATADIR], [datadir], [Where data are placed to.])
- dnl
- dnl @category Misc
- dnl @author Stepan Kasal <[email protected]>
- dnl @author Andreas Schwab <[email protected]>
- dnl @author Guido U. Draheim <[email protected]>
- dnl @author Alexandre Oliva
- dnl @version 2006-10-13
- dnl @license AllPermissive
- AC_DEFUN([AC_DEFINE_DIR], [
- prefix_NONE=
- exec_prefix_NONE=
- test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
- test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
- dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
- dnl refers to ${prefix}. Thus we have to use `eval' twice.
- eval ac_define_dir="\"[$]$2\""
- eval ac_define_dir="\"$ac_define_dir\""
- AC_SUBST($1, "$ac_define_dir")
- AC_DEFINE_UNQUOTED($1, "$ac_define_dir", [$3])
- test "$prefix_NONE" && prefix=NONE
- test "$exec_prefix_NONE" && exec_prefix=NONE
- ])
|
