panda3d/makepanda/makepanda.bat

@echo off

REM
REM Verify that we can find the 'makepanda' python script
REM and the python interpreter.  If we can find both, then
REM run 'makepanda'.
REM

set thirdparty=thirdparty
if defined MAKEPANDA_THIRDPARTY set thirdparty=%MAKEPANDA_THIRDPARTY%

if not exist makepanda\makepanda.py goto :missing1
if %PROCESSOR_ARCHITECTURE% == AMD64 goto :AMD64

if not exist %thirdparty%\win-python\python.exe goto :missing2
%thirdparty%\win-python\python.exe makepanda\makepanda.py %*
if errorlevel 1 if x%1 == x--slavebuild exit 1
goto done

:AMD64
if not exist %thirdparty%\win-python-x64\python.exe goto :missing2
%thirdparty%\win-python-x64\python.exe makepanda\makepanda.py %*
if errorlevel 1 if x%1 == x--slavebuild exit 1
goto done

:missing1
  echo You need to change directory to the root of the panda source tree
  echo before invoking makepanda.  For further install instructions, read 
  echo the installation instructions in the file doc/INSTALL-MK.
  goto done

:missing2
  echo You seem to be missing the 'thirdparty' directory.  You probably checked
  echo the source code out from sourceforge.  The sourceforge repository is
  echo missing the 'thirdparty' directory.  You will need to supplement the
  echo code by downloading the 'thirdparty' directory from www.panda3d.org
  goto done

:done