panda3d/CMakeLists.txt

if(CMAKE_SYSTEM_NAME STREQUAL iOS)
  cmake_minimum_required(VERSION 3.14)
else()
  cmake_minimum_required(VERSION 3.0.2)
endif()

set(CMAKE_DISABLE_SOURCE_CHANGES ON) # Must go before project() below
set(CMAKE_DISABLE_IN_SOURCE_BUILD ON) # Must go before project() below

if(CMAKE_VERSION VERSION_GREATER "3.11" OR POLICY CMP0072)
  # Prefer GLVND over libGL when available; this will be enabled by default
  # once the minimum CMake version is at least 3.11.
  cmake_policy(SET CMP0072 NEW)
endif()

if(CMAKE_VERSION VERSION_GREATER "3.12" OR POLICY CMP0074)
  # Needed for THIRDPARTY_DIRECTORY support; this will be enabled by default
  # once the minimum CMake version is at least 3.12.
  cmake_policy(SET CMP0074 NEW)
endif()

if(POLICY CMP0091)
  # Needed for CMake to pass /MD flag properly with non-VC generators.
  cmake_policy(SET CMP0091 NEW)
endif()

# Determine whether we are using a multi-config generator.
if(CMAKE_VERSION VERSION_GREATER "3.8")
  get_property(IS_MULTICONFIG GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
  # set_property(GLOBAL PROPERTY XCODE_EMIT_EFFECTIVE_PLATFORM_NAME OFF)
else()
  message(WARNING "Multi-configuration builds may not work properly when using
a CMake < 3.9. Making a guess if this is a multi-config generator.")
  if(DEFINED CMAKE_CONFIGURATION_TYPES)
    set(IS_MULTICONFIG ON)
  else()
    set(IS_MULTICONFIG OFF)
  endif()
endif()

# Define the type of build we are setting up.
set(_configs Standard Release RelWithDebInfo Debug MinSizeRel)
if(CMAKE_CXX_COMPILER_ID MATCHES "(AppleClang|Clang|GCC)")
  list(APPEND _configs Coverage)
endif()

if(IS_MULTICONFIG)
  message(STATUS "Using multi-configuration generator")
else()
  # Set the default CMAKE_BUILD_TYPE before calling project().
  if(NOT CMAKE_BUILD_TYPE)
    set(CMAKE_BUILD_TYPE Standard CACHE STRING "Choose the type of build." FORCE)
    message(STATUS "Using default build type ${CMAKE_BUILD_TYPE}")
  else()
    message(STATUS "Using build type ${CMAKE_BUILD_TYPE}")
  endif()
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${_configs})
endif()

# Figure out the version
set(_s "[\\t ]*") # CMake doesn't support \s*
file(STRINGS "setup.cfg" _version REGEX "^version${_s}=${_s}")
string(REGEX REPLACE "^.*=${_s}" "" _version "${_version}")
project(Panda3D VERSION ${_version})
unset(_version)
unset(_s)

enable_testing()

# Create some convenience variables for the build configuration intdir. One uses
# the build system's representation, while the other uses a generator expression.
string(REPLACE "$(EFFECTIVE_PLATFORM_NAME)" "" PANDA_CFG_INTDIR "${CMAKE_CFG_INTDIR}")
if(PANDA_CFG_INTDIR STREQUAL ".")
  set(PANDA_CFG_INTDIR_GEN ".")
else()
  set(PANDA_CFG_INTDIR_GEN "$<CONFIG>")
endif()

# Add generic modules to cmake module path,
# and add Panda3D specific modules to cmake module path
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules/")
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/macros/")


# Include modules builtin to CMake
include(GNUInstallDirs)     # Defines CMAKE_INSTALL_<dir> variables

# Include global modules needed for configure scripts
include(PackageConfig)      # Defines package_option
include(PerConfigOption)    # Defines per_config_option

# Configure Panda3D
include(dtool/CompilerFlags.cmake)
include(dtool/PandaVersion.cmake)
include(dtool/Package.cmake)
include(dtool/Config.cmake)

# If cross compiling, find the host's Panda3D, if needed.
if(CMAKE_CROSSCOMPILING)
  if(INTERROGATE_PYTHON_INTERFACE)
    find_package(Panda3D REQUIRED COMPONENTS Core OPTIONAL_COMPONENTS Tools CONFIG)
    set_target_properties(Panda3D::Core::interrogate Panda3D::Core::interrogate_module PROPERTIES IMPORTED_GLOBAL TRUE)
  else()
    find_package(Panda3D COMPONENTS Tools CONFIG)
  endif()

  if(TARGET Panda3D::Tools::pzip)
    set_target_properties(Panda3D::Tools::pzip PROPERTIES IMPORTED_GLOBAL TRUE)
  endif()
endif()

# Include global modules
include(AddBisonTarget)     # Defines add_bison_target function
include(AddFlexTarget)      # Defines add_flex_target function
include(BuildMetalib)       # Defines add_component_library AND add_metalib
include(CompositeSources)   # Defines composite_sources function
include(Python)             # Defines add_python_target AND install_python_package
include(Interrogate)        # Defines target_interrogate AND add_python_module
include(RunPzip)            # Defines run_pzip function
include(Versioning)         # Hooks 'add_library' to apply VERSION/SOVERSION

# Determine which trees to build.
option(BUILD_DTOOL "Build the dtool source tree." ON)
option(BUILD_PANDA "Build the panda source tree." ON)
option(BUILD_DIRECT "Build the direct source tree." ON)
option(BUILD_PANDATOOL "Build the pandatool source tree." ON)
option(BUILD_DEPLOYSTUB "Build deploy-stub. Will also be built if BUILD_PANDATOOL is true." ON)
option(BUILD_CONTRIB "Build the contrib source tree." ON)
option(BUILD_MODELS "Build/install the built-in models." ON)

if(CMAKE_SYSTEM_NAME STREQUAL iOS)
  set(BUILD_PANDATOOL OFF)
endif()

# Include Panda3D packages
if(BUILD_DTOOL)
  add_subdirectory(dtool "${CMAKE_BINARY_DIR}/dtool")
endif()

if(BUILD_PANDA)
  add_subdirectory(panda "${CMAKE_BINARY_DIR}/panda")
endif()

if(BUILD_DIRECT)
  add_subdirectory(direct "${CMAKE_BINARY_DIR}/direct")
endif()

if(BUILD_PANDATOOL OR BUILD_DEPLOYSTUB)
  add_subdirectory(pandatool "${CMAKE_BINARY_DIR}/pandatool")
endif()

if(BUILD_CONTRIB)
  add_subdirectory(contrib "${CMAKE_BINARY_DIR}/contrib")
endif()

if(BUILD_MODELS)
  run_pzip(models
    "${CMAKE_CURRENT_SOURCE_DIR}/models/"
    "${PROJECT_BINARY_DIR}/${PANDA_CFG_INTDIR}/models"
    *.egg)
  run_pzip(dmodels
    "${CMAKE_CURRENT_SOURCE_DIR}/dmodels/src/"
    "${PROJECT_BINARY_DIR}/${PANDA_CFG_INTDIR}/models"
    *.egg)

  add_custom_command(TARGET models
                     POST_BUILD
                     COMMAND ${CMAKE_COMMAND}
                             -DSOURCE="${CMAKE_CURRENT_SOURCE_DIR}/models/maps/"
                             -DDESTINATION="${PANDA_OUTPUT_DIR}/models/maps"
                             -P ${PROJECT_SOURCE_DIR}/cmake/scripts/CopyPattern.cmake
                     COMMENT "Copying models/maps")
  add_custom_command(TARGET dmodels
                     POST_BUILD
                     COMMAND ${CMAKE_COMMAND}
                             -DSOURCE="${CMAKE_CURRENT_SOURCE_DIR}/dmodels/src/"
                             -DDESTINATION="${PANDA_OUTPUT_DIR}/models"
                             -DFILES_MATCHING="PATTERN;*.rgb;PATTERN;*.png;PATTERN;*.jpg;PATTERN;*.wav"
                             -P ${PROJECT_SOURCE_DIR}/cmake/scripts/CopyPattern.cmake
                     COMMENT "Copying dmodels' assets")

  install(DIRECTORY "${PANDA_OUTPUT_DIR}/models"
    COMPONENT Models DESTINATION ${CMAKE_INSTALL_DATADIR}/panda3d)
endif()

if(INTERROGATE_PYTHON_INTERFACE)
  # If we built the Python interface, run the test suite.  Note, we do NOT test
  # for pytest before adding this test.  If the user doesn't have pytest, we'd
  # like for the tests to fail.

  # In the Coverage configuration, we also require pytest-cov

  add_test(NAME pytest
    COMMAND "${PYTHON_EXECUTABLE}" -m pytest "${PROJECT_SOURCE_DIR}/tests"
    $<$<CONFIG:Coverage>:--cov=.>
    WORKING_DIRECTORY "${PANDA_OUTPUT_DIR}")
endif()

# Generate the Panda3DConfig.cmake file so find_package(Panda3D) works, and
# also register the build directory with CMake's package registry.

file(COPY "${PROJECT_SOURCE_DIR}/cmake/install/Panda3DConfig.cmake"
  DESTINATION "${PROJECT_BINARY_DIR}")
install(FILES "${PROJECT_SOURCE_DIR}/cmake/install/Panda3DConfig.cmake"
  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/Panda3D")

include(CMakePackageConfigHelpers)
write_basic_package_version_file(
  "${PROJECT_BINARY_DIR}/Panda3DConfigVersion.cmake"
  VERSION "${PROJECT_VERSION}"
  COMPATIBILITY AnyNewerVersion)
install(FILES "${PROJECT_BINARY_DIR}/Panda3DConfigVersion.cmake"
  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/Panda3D")

if(NOT CMAKE_CROSSCOMPILING)
  export(PACKAGE Panda3D)
endif()