Ported Sprites, StaticScene & AnimatingScene samples to AngelScript.

Bin/Data/Scripts/03_Sprites.as

@@ -0,0 +1,108 @@
+// Moving sprites example.
+// This sample demonstrates:
+//     - Adding Sprite elements to the UI;
+//     - Storing custom data (sprite velocity) inside UI elements;
+//     - Handling frame update events in which the sprites are moved;
+
+#include "Utilities/Sample.as"
+
+// Number of sprites to draw
+const uint NUM_SPRITES = 100;
+
+Array<Sprite@> sprites;
+
+void Start()
+{
+    // Execute the common startup for samples
+    SampleStart();
+
+    // Create the sprites to the user interface
+    CreateSprites();
+
+    // Hook up to the frame update events
+    SubscribeToEvents();
+}
+
+void CreateSprites()
+{
+    // Get rendering window size as floats
+    float width = graphics.width;
+    float height = graphics.height;
+
+    // Get the Urho3D fish texture
+    Texture2D@ decalTex = cache.GetResource("Texture2D", "Textures/UrhoDecal.dds");
+
+    for (uint i = 0; i < NUM_SPRITES; ++i)
+    {
+        // Create a new sprite, set it to use the texture
+        Sprite@ sprite = Sprite();
+        sprite.texture = decalTex;
+
+        // The UI root element is as big as the rendering window, set random position within it
+        sprite.position = Vector2(Random() * width, Random() * height);
+
+        // Set sprite size & hotspot in its center
+        sprite.size = IntVector2(128, 128);
+        sprite.hotSpot = IntVector2(64, 64);
+
+        // Set random rotation in degrees and random scale
+        sprite.rotation = Random() * 360.0f;
+        sprite.SetScale(Random(1.0f) + 0.5f);
+
+        // Set random color and additive blending mode
+        sprite.color = Color(Random(0.5f) + 0.5f, Random(0.5f) + 0.5f, Random(0.5f) + 0.5f);
+        sprite.blendMode = BLEND_ADD;
+
+        // Add as a child of the root UI element
+        ui.root.AddChild(sprite);
+
+        // Store sprite's velocity as a custom variable
+        sprite.vars["Velocity"] = Vector2(Random(200.0f) - 100.0f, Random(200.0f) - 100.0f);
+
+        // Store sprites to our own container for easy movement update iteration
+        sprites.Push(sprite);
+    }
+}
+
+void MoveSprites(float timeStep)
+{
+    float width = graphics.width;
+    float height = graphics.height;
+
+    // Go through all sprites
+    for (uint i = 0; i < sprites.length; ++i)
+    {
+        Sprite@ sprite = sprites[i];
+
+        // Rotate
+        float newRot = sprite.rotation + timeStep * 30.0f;
+        sprite.rotation = newRot;
+
+        // Move, wrap around rendering window edges
+        Vector2 newPos = sprite.position + sprite.vars["Velocity"].GetVector2() * timeStep;
+        if (newPos.x < 0.0f)
+            newPos.x += width;
+        if (newPos.x >= width)
+            newPos.x -= width;
+        if (newPos.y < 0.0f)
+            newPos.y += height;
+        if (newPos.y >= height)
+            newPos.y -= height;
+        sprite.position = newPos;
+    }
+}
+
+void SubscribeToEvents()
+{
+    // Subscribe HandleUpdate() function for processing update events
+    SubscribeToEvent("Update", "HandleUpdate");
+}
+
+void HandleUpdate(StringHash eventType, VariantMap& eventData)
+{
+    // Take the frame time step, which is stored as a float
+    float timeStep = eventData["TimeStep"].GetFloat();
+
+    // Move sprites, scale movement with time step
+    MoveSprites(timeStep);
+}

Bin/Data/Scripts/04_StaticScene.as

@@ -0,0 +1,155 @@
+// Static 3D scene example.
+// This sample demonstrates:
+//     - Creating a 3D scene with static content;
+//     - Displaying the scene using the Renderer subsystem;
+//     - Handling keyboard and mouse input to move a freelook camera;
+
+#include "Utilities/Sample.as"
+
+Scene@ scene_;
+Node@ cameraNode;
+float yaw = 0.0f;
+float pitch = 0.0f;
+
+void Start()
+{
+    // Execute the common startup for samples
+    SampleStart();
+
+    // Create the scene content
+    CreateScene();
+
+    // Create the UI content
+    CreateInstructions();
+
+    // Setup the viewport for displaying the scene
+    SetupViewport();
+
+    // Hook up to the frame update events
+    SubscribeToEvents();
+}
+
+void CreateScene()
+{
+    scene_ = Scene();
+
+    // Create the Octree component to the scene. This is required before adding any drawable components, or else nothing will
+    // show up. The default octree volume will be from (-1000, -1000, -1000) to (1000, 1000, 1000) in world coordinates; it
+    // is also legal to place objects outside the volume but their visibility can then not be checked in a hierarchically
+    // optimizing manner
+    scene_.CreateComponent("Octree");
+
+    // Create a child scene node (at world origin) and a StaticModel component into it. Set the StaticModel to show a simple
+    // plane mesh with a "stone" material. Note that naming the scene nodes is optional. Scale the scene node larger
+    // (100 x 100 world units)
+    Node@ planeNode = scene_.CreateChild("Plane");
+    planeNode.scale = Vector3(100.0f, 1.0f, 100.0f);
+    StaticModel@ planeObject = planeNode.CreateComponent("StaticModel");
+    planeObject.model = cache.GetResource("Model", "Models/Plane.mdl");
+    planeObject.material = cache.GetResource("Material", "Materials/StoneTiled.xml");
+
+    // Create a directional light to the world so that we can see something. The light scene node's orientation controls the
+    // light direction; we will use the SetDirection() function which calculates the orientation from a forward direction vector.
+    // The light will use default settings (white light, no shadows)
+    Node@ lightNode = scene_.CreateChild("DirectionalLight");
+    lightNode.direction = Vector3(0.6f, -1.0f, 0.8f); // The direction vector does not need to be normalized
+    Light@ light = lightNode.CreateComponent("Light");
+    light.lightType = LIGHT_DIRECTIONAL;
+
+    // Create more StaticModel objects to the scene, randomly positioned, rotated and scaled. For rotation, we construct a
+    // quaternion from Euler angles where the Y angle (rotation about the Y axis) is randomized. The mushroom model contains
+    // LOD levels, so the StaticModel component will automatically select the LOD level according to the view distance (you'll
+    // see the model get simpler as it moves further away). Finally, rendering a large number of the same object with the
+    // same material allows instancing to be used, if the GPU supports it. This reduces the amount of CPU work in rendering the
+    // scene.
+    const uint NUM_OBJECTS = 200;
+    for (uint i = 0; i < NUM_OBJECTS; ++i)
+    {
+        Node@ mushroomNode = scene_.CreateChild("Mushroom");
+        mushroomNode.position = Vector3(Random(90.0f) - 45.0f, 0.0f, Random(90.0f) - 45.0f);
+        mushroomNode.rotation = Quaternion(0.0f, Random(360.0f), 0.0f);
+        mushroomNode.SetScale(0.5f + Random(2.0f));
+        StaticModel@ mushroomObject = mushroomNode.CreateComponent("StaticModel");
+        mushroomObject.model = cache.GetResource("Model", "Models/Mushroom.mdl");
+        mushroomObject.material = cache.GetResource("Material", "Materials/Mushroom.xml");
+    }
+
+    // Create a scene node for the camera, which we will move around
+    // The camera will use default settings (1000 far clip distance, 45 degrees FOV, set aspect ratio automatically)
+    cameraNode = scene_.CreateChild("Camera");
+    cameraNode.CreateComponent("Camera");
+
+    // Set an initial position for the camera scene node above the plane
+    cameraNode.position = Vector3(0.0f, 5.0f, 0.0f);
+}
+
+void CreateInstructions()
+{
+    // Construct new Text object, set string to display and font to use
+    Text@ instructionText = ui.root.CreateChild("Text");
+    instructionText.text = "Use WASD keys and mouse to move";
+    instructionText.SetFont(cache.GetResource("Font", "Fonts/Anonymous Pro.ttf"), 15);
+
+    // Position the text relative to the screen center
+    instructionText.horizontalAlignment = HA_CENTER;
+    instructionText.verticalAlignment= VA_CENTER;
+    instructionText.SetPosition(0, ui.root.height / 4);
+}
+
+void SetupViewport()
+{
+    // Set up a viewport to the Renderer subsystem so that the 3D scene can be seen. We need to define the scene and the camera
+    // at minimum. Additionally we could configure the viewport screen size and the rendering path (eg. forward / deferred) to
+    // use, but now we just use full screen and default render path configured in the engine command line options
+    Viewport@ viewport = Viewport(scene_, cameraNode.GetComponent("Camera"));
+    renderer.viewports[0] = viewport;
+}
+
+void MoveCamera(float timeStep)
+{
+    // Do not move if the UI has a focused element (the console)
+    if (ui.focusElement !is null)
+        return;
+
+    // Movement speed as world units per second
+    const float MOVE_SPEED = 20.0f;
+    // Mouse sensitivity as degrees per pixel
+    const float MOUSE_SENSITIVITY = 0.1f;
+
+    // Use this frame's mouse motion to adjust camera node yaw and pitch. Clamp the pitch between -90 and 90 degrees
+    IntVector2 mouseMove = input.mouseMove;
+    yaw += MOUSE_SENSITIVITY * mouseMove.x;
+    pitch += MOUSE_SENSITIVITY * mouseMove.y;
+    pitch = Clamp(pitch, -90.0f, 90.0f);
+
+    // Construct new orientation for the camera scene node from yaw and pitch. Roll is fixed to zero
+    cameraNode.rotation = Quaternion(pitch, yaw, 0.0f);
+
+    // Read WASD keys and move the camera scene node to the corresponding direction if they are pressed
+    // Use the TranslateRelative() function to move relative to the node's orientation. Alternatively we could
+    // multiply the desired direction with the node's orientation quaternion, and use just Translate()
+    if (input.keyDown['W'])
+        cameraNode.TranslateRelative(Vector3(0.0f, 0.0f, 1.0f) * MOVE_SPEED * timeStep);
+    if (input.keyDown['S'])
+        cameraNode.TranslateRelative(Vector3(0.0f, 0.0f, -1.0f) * MOVE_SPEED * timeStep);
+    if (input.keyDown['A'])
+        cameraNode.TranslateRelative(Vector3(-1.0f, 0.0f, 0.0f) * MOVE_SPEED * timeStep);
+    if (input.keyDown['D'])
+        cameraNode.TranslateRelative(Vector3(1.0f, 0.0f, 0.0f) * MOVE_SPEED * timeStep);
+}
+
+void SubscribeToEvents()
+{
+    // Subscribe HandleUpdate() function for processing update events
+    SubscribeToEvent("Update", "HandleUpdate");
+}
+
+void HandleUpdate(StringHash eventType, VariantMap& eventData)
+{
+    // Take the frame time step, which is stored as a float
+    float timeStep = eventData["TimeStep"].GetFloat();
+
+    // Move the camera, scale movement with time step
+    MoveCamera(timeStep);
+}
+

Bin/Data/Scripts/05_AnimatingScene.as

@@ -0,0 +1,164 @@
+// Animating 3D scene example.
+// This sample demonstrates:
+//     - Creating a 3D scene and using a script component to animate the objects;
+//     - Controlling scene ambience with the Zone component;
+//     - Attaching a light to an object (the camera);
+
+#include "Utilities/Sample.as"
+
+Scene@ scene_;
+Node@ cameraNode;
+float yaw = 0.0f;
+float pitch = 0.0f;
+
+void Start()
+{
+    // Execute the common startup for samples
+    SampleStart();
+
+    // Create the scene content
+    CreateScene();
+
+    // Create the UI content
+    CreateInstructions();
+
+    // Setup the viewport for displaying the scene
+    SetupViewport();
+
+    // Hook up to the frame update events
+    SubscribeToEvents();
+}
+
+void CreateScene()
+{
+    scene_ = Scene();
+
+    // Create the Octree component to the scene so that drawable objects can be rendered. Use default volume
+    // (-1000, -1000, -1000) to (1000, 1000, 1000)
+    scene_.CreateComponent("Octree");
+
+    // Create a Zone component into a child scene node. The Zone controls ambient lighting and fog settings. Like the Octree,
+    // it also defines its volume with a bounding box, but can be rotated (so it does not need to be aligned to the world X, Y
+    // and Z axes.) Drawable objects "pick up" the zone they belong to and use it when rendering; several zones can exist
+    Node@ zoneNode = scene_.CreateChild("Zone");
+    Zone@ zone = zoneNode.CreateComponent("Zone");
+    // Set same volume as the Octree, set a close bluish fog and some ambient light
+    zone.boundingBox = BoundingBox(-1000.0f, 1000.0f);
+    zone.ambientColor = Color(0.05f, 0.1f, 0.15f);
+    zone.fogColor = Color(0.1f, 0.2f, 0.3f);
+    zone.fogStart = 10.0f;
+    zone.fogEnd = 100.0f;
+
+    // Create randomly positioned and oriented box StaticModels in the scene
+    const uint NUM_OBJECTS = 2000;
+    for (uint i = 0; i < NUM_OBJECTS; ++i)
+    {
+        Node@ boxNode = scene_.CreateChild("Box");
+        boxNode.position = Vector3(Random(200.0f) - 100.0f, Random(200.0f) - 100.0f, Random(200.0f) - 100.0f);
+        // Orient using random pitch, yaw and roll Euler angles
+        boxNode.rotation = Quaternion(Random(360.0f), Random(360.0f), Random(360.0f));
+        StaticModel@ boxObject = boxNode.CreateComponent("StaticModel");
+        boxObject.model = cache.GetResource("Model", "Models/Box.mdl");
+        boxObject.material = cache.GetResource("Material", "Materials/Stone.xml");
+
+        // Add the Rotator script object which will rotate the scene node each frame, when the scene sends its update event.
+        // Note that creating a script object into a scene node requires both a script file reference (scriptFile is the file
+        // we are executing now) and the class name. On the C++ side, this will create a ScriptInstance component to the node,
+        // which holds the script object. Then, simply set same rotation speed for all objects
+        Rotator@ rotator = cast<Rotator>(boxNode.CreateScriptObject(scriptFile, "Rotator"));
+        rotator.rotationSpeed = Vector3(10.0f, 20.0f, 30.0f);
+    }
+
+    // Create the camera. Let the starting position be at the world origin. As the fog limits maximum visible distance, we can
+    // bring the far clip plane closer for more effective culling of distant objects
+    cameraNode = scene_.CreateChild("Camera");
+    Camera@ camera = cameraNode.CreateComponent("Camera");
+    camera.farClip = 100.0f;
+
+    // Create a point light to the camera scene node
+    Light@ light = cameraNode.CreateComponent("Light");
+    light.lightType = LIGHT_POINT;
+    light.range = 30.0f;
+}
+
+void CreateInstructions()
+{
+    // Construct new Text object, set string to display and font to use
+    Text@ instructionText = ui.root.CreateChild("Text");
+    instructionText.text = "Use WASD keys and mouse to move";
+    instructionText.SetFont(cache.GetResource("Font", "Fonts/Anonymous Pro.ttf"), 15);
+
+    // Position the text relative to the screen center
+    instructionText.horizontalAlignment = HA_CENTER;
+    instructionText.verticalAlignment= VA_CENTER;
+    instructionText.SetPosition(0, ui.root.height / 4);
+}
+
+void SetupViewport()
+{
+    // Set up a viewport to the Renderer subsystem so that the 3D scene can be seen. We need to define the scene and the camera
+    // at minimum. Additionally we could configure the viewport screen size and the rendering path (eg. forward / deferred) to
+    // use, but now we just use full screen and default render path configured in the engine command line options
+    Viewport@ viewport = Viewport(scene_, cameraNode.GetComponent("Camera"));
+    renderer.viewports[0] = viewport;
+}
+
+void MoveCamera(float timeStep)
+{
+    // Do not move if the UI has a focused element (the console)
+    if (ui.focusElement !is null)
+        return;
+
+    // Movement speed as world units per second
+    const float MOVE_SPEED = 20.0f;
+    // Mouse sensitivity as degrees per pixel
+    const float MOUSE_SENSITIVITY = 0.1f;
+
+    // Use this frame's mouse motion to adjust camera node yaw and pitch. Clamp the pitch between -90 and 90 degrees
+    IntVector2 mouseMove = input.mouseMove;
+    yaw += MOUSE_SENSITIVITY * mouseMove.x;
+    pitch += MOUSE_SENSITIVITY * mouseMove.y;
+    pitch = Clamp(pitch, -90.0f, 90.0f);
+
+    // Construct new orientation for the camera scene node from yaw and pitch. Roll is fixed to zero
+    cameraNode.rotation = Quaternion(pitch, yaw, 0.0f);
+
+    // Read WASD keys and move the camera scene node to the corresponding direction if they are pressed
+    // Use the TranslateRelative() function to move relative to the node's orientation. Alternatively we could
+    // multiply the desired direction with the node's orientation quaternion, and use just Translate()
+    if (input.keyDown['W'])
+        cameraNode.TranslateRelative(Vector3(0.0f, 0.0f, 1.0f) * MOVE_SPEED * timeStep);
+    if (input.keyDown['S'])
+        cameraNode.TranslateRelative(Vector3(0.0f, 0.0f, -1.0f) * MOVE_SPEED * timeStep);
+    if (input.keyDown['A'])
+        cameraNode.TranslateRelative(Vector3(-1.0f, 0.0f, 0.0f) * MOVE_SPEED * timeStep);
+    if (input.keyDown['D'])
+        cameraNode.TranslateRelative(Vector3(1.0f, 0.0f, 0.0f) * MOVE_SPEED * timeStep);
+}
+
+void SubscribeToEvents()
+{
+    // Subscribe HandleUpdate() function for processing update events
+    SubscribeToEvent("Update", "HandleUpdate");
+}
+
+void HandleUpdate(StringHash eventType, VariantMap& eventData)
+{
+    // Take the frame time step, which is stored as a float
+    float timeStep = eventData["TimeStep"].GetFloat();
+
+    // Move the camera, scale movement with time step
+    MoveCamera(timeStep);
+}
+
+// Rotator script object. Script objects to be added to a scene node must implement the ScriptObject interface
+class Rotator : ScriptObject
+{
+    Vector3 rotationSpeed;
+
+    // Update is called during variable timestep scene update
+    void Update(float timeStep)
+    {
+        node.Rotate(Quaternion(rotationSpeed.x * timeStep, rotationSpeed.y * timeStep, rotationSpeed.z * timeStep));
+    }
+}

Source/Samples/03_Sprites/Sprites.cpp

@@ -50,7 +50,7 @@ void Sprites::Start()
     // Execute base class startup
     Sample::Start();
 
-    // Create the sprites to the UI interface
+    // Create the sprites to the user interface
     CreateSprites();
 
     // Hook up to the frame update events