keep old Md5/SHA1 until 3.0 release

std/haxe/Md5.hx

@@ -0,0 +1,245 @@
+/*
+ * Copyright (c) 2005, The haXe Project Contributors
+ * All rights reserved.
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions are met:
+ *
+ *   - Redistributions of source code must retain the above copyright
+ *     notice, this list of conditions and the following disclaimer.
+ *   - Redistributions in binary form must reproduce the above copyright
+ *     notice, this list of conditions and the following disclaimer in the
+ *     documentation and/or other materials provided with the distribution.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE HAXE PROJECT CONTRIBUTORS "AS IS" AND ANY
+ * EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+ * DISCLAIMED. IN NO EVENT SHALL THE HAXE PROJECT CONTRIBUTORS BE LIABLE FOR
+ * ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+ * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+ * CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH
+ * DAMAGE.
+ */
+package haxe;
+
+#if !haxe3
+
+/**
+	Creates a MD5 of a String.
+**/
+class Md5 {
+
+	public static function encode( s : String ) : String {
+		#if neko
+			return untyped new String(base_encode(make_md5(s.__s),"0123456789abcdef".__s));
+		#elseif php
+			return untyped __call__("md5", s);
+		#else
+			return new Md5().doEncode(s);
+		#end
+	}
+
+	#if neko
+	static var base_encode = neko.Lib.load("std","base_encode",2);
+	static var make_md5 = neko.Lib.load("std","make_md5",1);
+	#elseif !php
+
+/*
+ * A JavaScript implementation of the RSA Data Security, Inc. MD5 Message
+ * Digest Algorithm, as defined in RFC 1321.
+ * Copyright (C) Paul Johnston 1999 - 2000.
+ * Updated by Greg Holt 2000 - 2001.
+ * See http://pajhome.org.uk/site/legal.html for details.
+ */
+
+	function new() {
+	}
+
+	function bitOR(a, b){
+		var lsb = (a & 0x1) | (b & 0x1);
+		var msb31 = (a >>> 1) | (b >>> 1);
+		return (msb31 << 1) | lsb;
+	}
+
+	function bitXOR(a, b){
+		var lsb = (a & 0x1) ^ (b & 0x1);
+		var msb31 = (a >>> 1) ^ (b >>> 1);
+		return (msb31 << 1) | lsb;
+	}
+
+	function bitAND(a, b){
+		var lsb = (a & 0x1) & (b & 0x1);
+		var msb31 = (a >>> 1) & (b >>> 1);
+		return (msb31 << 1) | lsb;
+	}
+
+	function addme(x, y) {
+		var lsw = (x & 0xFFFF)+(y & 0xFFFF);
+		var msw = (x >> 16)+(y >> 16)+(lsw >> 16);
+		return (msw << 16) | (lsw & 0xFFFF);
+	}
+
+	function rhex( num ){
+		var str = "";
+		var hex_chr = "0123456789abcdef";
+		for( j in 0...4 ){
+			str += hex_chr.charAt((num >> (j * 8 + 4)) & 0x0F) +
+						 hex_chr.charAt((num >> (j * 8)) & 0x0F);
+		}
+		return str;
+	}
+
+	function str2blks( str : String ){
+		var nblk = ((str.length + 8) >> 6) + 1;
+		var blks = new Array();
+
+		//preallocate size
+		var blksSize = nblk * 16;
+		#if (neko || cs || cpp || java)
+		blks[blksSize - 1] = 0;
+		#end
+
+		#if !(cpp || cs) //C++ and C# will already initialize them with zeroes.
+		for( i in 0...blksSize ) blks[i] = 0;
+		#end
+
+		var i = 0;
+		while( i < str.length ) {
+			blks[i >> 2] |= str.charCodeAt(i) << (((str.length * 8 + i) % 4) * 8);
+			i++;
+		}
+		blks[i >> 2] |= 0x80 << (((str.length * 8 + i) % 4) * 8);
+		var l = str.length * 8;
+		var k = nblk * 16 - 2;
+		blks[k] = (l & 0xFF);
+		blks[k] |= ((l >>> 8) & 0xFF) << 8;
+		blks[k] |= ((l >>> 16) & 0xFF) << 16;
+		blks[k] |= ((l >>> 24) & 0xFF) << 24;
+		return blks;
+	}
+
+	function rol(num, cnt){
+		return (num << cnt) | (num >>> (32 - cnt));
+	}
+
+	function cmn(q, a, b, x, s, t){
+		return addme(rol((addme(addme(a, q), addme(x, t))), s), b);
+	}
+
+	function ff(a, b, c, d, x, s, t){
+		return cmn(bitOR(bitAND(b, c), bitAND((~b), d)), a, b, x, s, t);
+	}
+
+	function gg(a, b, c, d, x, s, t){
+		return cmn(bitOR(bitAND(b, d), bitAND(c, (~d))), a, b, x, s, t);
+	}
+
+	function hh(a, b, c, d, x, s, t){
+		return cmn(bitXOR(bitXOR(b, c), d), a, b, x, s, t);
+	}
+
+	function ii(a, b, c, d, x, s, t){
+		return cmn(bitXOR(c, bitOR(b, (~d))), a, b, x, s, t);
+	}
+
+	function doEncode( str:String ) : String {
+
+		var x = str2blks(str);
+		var a =  1732584193;
+		var b = -271733879;
+		var c = -1732584194;
+		var d =  271733878;
+
+		var step;
+
+		var i = 0;
+		while( i < x.length )  {
+			var olda = a;
+			var oldb = b;
+			var oldc = c;
+			var oldd = d;
+
+			step = 0;
+			a = ff(a, b, c, d, x[i+ 0], 7 , -680876936);
+			d = ff(d, a, b, c, x[i+ 1], 12, -389564586);
+			c = ff(c, d, a, b, x[i+ 2], 17,  606105819);
+			b = ff(b, c, d, a, x[i+ 3], 22, -1044525330);
+			a = ff(a, b, c, d, x[i+ 4], 7 , -176418897);
+			d = ff(d, a, b, c, x[i+ 5], 12,  1200080426);
+			c = ff(c, d, a, b, x[i+ 6], 17, -1473231341);
+			b = ff(b, c, d, a, x[i+ 7], 22, -45705983);
+			a = ff(a, b, c, d, x[i+ 8], 7 ,  1770035416);
+			d = ff(d, a, b, c, x[i+ 9], 12, -1958414417);
+			c = ff(c, d, a, b, x[i+10], 17, -42063);
+			b = ff(b, c, d, a, x[i+11], 22, -1990404162);
+			a = ff(a, b, c, d, x[i+12], 7 ,  1804603682);
+			d = ff(d, a, b, c, x[i+13], 12, -40341101);
+			c = ff(c, d, a, b, x[i+14], 17, -1502002290);
+			b = ff(b, c, d, a, x[i+15], 22,  1236535329);
+			a = gg(a, b, c, d, x[i+ 1], 5 , -165796510);
+			d = gg(d, a, b, c, x[i+ 6], 9 , -1069501632);
+			c = gg(c, d, a, b, x[i+11], 14,  643717713);
+			b = gg(b, c, d, a, x[i+ 0], 20, -373897302);
+			a = gg(a, b, c, d, x[i+ 5], 5 , -701558691);
+			d = gg(d, a, b, c, x[i+10], 9 ,  38016083);
+			c = gg(c, d, a, b, x[i+15], 14, -660478335);
+			b = gg(b, c, d, a, x[i+ 4], 20, -405537848);
+			a = gg(a, b, c, d, x[i+ 9], 5 ,  568446438);
+			d = gg(d, a, b, c, x[i+14], 9 , -1019803690);
+			c = gg(c, d, a, b, x[i+ 3], 14, -187363961);
+			b = gg(b, c, d, a, x[i+ 8], 20,  1163531501);
+			a = gg(a, b, c, d, x[i+13], 5 , -1444681467);
+			d = gg(d, a, b, c, x[i+ 2], 9 , -51403784);
+			c = gg(c, d, a, b, x[i+ 7], 14,  1735328473);
+			b = gg(b, c, d, a, x[i+12], 20, -1926607734);
+			a = hh(a, b, c, d, x[i+ 5], 4 , -378558);
+			d = hh(d, a, b, c, x[i+ 8], 11, -2022574463);
+			c = hh(c, d, a, b, x[i+11], 16,  1839030562);
+			b = hh(b, c, d, a, x[i+14], 23, -35309556);
+			a = hh(a, b, c, d, x[i+ 1], 4 , -1530992060);
+			d = hh(d, a, b, c, x[i+ 4], 11,  1272893353);
+			c = hh(c, d, a, b, x[i+ 7], 16, -155497632);
+			b = hh(b, c, d, a, x[i+10], 23, -1094730640);
+			a = hh(a, b, c, d, x[i+13], 4 ,  681279174);
+			d = hh(d, a, b, c, x[i+ 0], 11, -358537222);
+			c = hh(c, d, a, b, x[i+ 3], 16, -722521979);
+			b = hh(b, c, d, a, x[i+ 6], 23,  76029189);
+			a = hh(a, b, c, d, x[i+ 9], 4 , -640364487);
+			d = hh(d, a, b, c, x[i+12], 11, -421815835);
+			c = hh(c, d, a, b, x[i+15], 16,  530742520);
+			b = hh(b, c, d, a, x[i+ 2], 23, -995338651);
+			a = ii(a, b, c, d, x[i+ 0], 6 , -198630844);
+			d = ii(d, a, b, c, x[i+ 7], 10,  1126891415);
+			c = ii(c, d, a, b, x[i+14], 15, -1416354905);
+			b = ii(b, c, d, a, x[i+ 5], 21, -57434055);
+			a = ii(a, b, c, d, x[i+12], 6 ,  1700485571);
+			d = ii(d, a, b, c, x[i+ 3], 10, -1894986606);
+			c = ii(c, d, a, b, x[i+10], 15, -1051523);
+			b = ii(b, c, d, a, x[i+ 1], 21, -2054922799);
+			a = ii(a, b, c, d, x[i+ 8], 6 ,  1873313359);
+			d = ii(d, a, b, c, x[i+15], 10, -30611744);
+			c = ii(c, d, a, b, x[i+ 6], 15, -1560198380);
+			b = ii(b, c, d, a, x[i+13], 21,  1309151649);
+			a = ii(a, b, c, d, x[i+ 4], 6 , -145523070);
+			d = ii(d, a, b, c, x[i+11], 10, -1120210379);
+			c = ii(c, d, a, b, x[i+ 2], 15,  718787259);
+			b = ii(b, c, d, a, x[i+ 9], 21, -343485551);
+
+			a = addme(a, olda);
+			b = addme(b, oldb);
+			c = addme(c, oldc);
+			d = addme(d, oldd);
+
+			i += 16;
+		}
+		return rhex(a) + rhex(b) + rhex(c) + rhex(d);
+	}
+
+	#end
+
+
+}
+
+#end

std/haxe/SHA1.hx

@@ -0,0 +1,157 @@
+/*
+ * Copyright (c) 2005-2010, The haXe Project Contributors
+ * All rights reserved.
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions are met:
+ *
+ *   - Redistributions of source code must retain the above copyright
+ *     notice, this list of conditions and the following disclaimer.
+ *   - Redistributions in binary form must reproduce the above copyright
+ *     notice, this list of conditions and the following disclaimer in the
+ *     documentation and/or other materials provided with the distribution.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE HAXE PROJECT CONTRIBUTORS "AS IS" AND ANY
+ * EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+ * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+ * DISCLAIMED. IN NO EVENT SHALL THE HAXE PROJECT CONTRIBUTORS BE LIABLE FOR
+ * ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+ * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+ * CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH
+ * DAMAGE.
+ */
+package haxe;
+
+#if !haxe3
+
+import haxe.Int32;
+
+class SHA1 {
+
+	static var hex_chr = "0123456789abcdef";
+
+	inline static function newInt32( left:Int, right:Int ) : Int32 {
+		var result = Int32.ofInt(left);
+		result = Int32.shl(result, 16);
+		return Int32.add(result, Int32.ofInt(right));
+	}
+
+	public static function encode( s:String ) : String {
+		var x = str2blks_SHA1( s );
+		var w = new Array<Int32>();
+
+		var a = newInt32(0x6745, 0x2301);
+		var b = newInt32(0xEFCD, 0xAB89);
+		var c = newInt32(0x98BA, 0xDCFE);
+		var d = newInt32(0x1032, 0x5476);
+		var e = newInt32(0xC3D2, 0xE1F0);
+
+		var i = 0;
+		while( i < x.length ) {
+			var olda = a;
+			var oldb = b;
+			var oldc = c;
+			var oldd = d;
+			var olde = e;
+
+			var j = 0;
+			while( j < 80 ) {
+				if(j < 16)
+					w[j] = x[i + j];
+				else
+					w[j] = rol(Int32.xor(Int32.xor(Int32.xor(w[j-3], w[j-8]), w[j-14]), w[j-16]), 1);
+				var t = add(add(rol(a, 5), ft(Int32.ofInt(j), b, c, d)), add(add(e, w[j]), kt(Int32.ofInt(j))));
+				e = d;
+				d = c;
+				c = rol(b, 30);
+				b = a;
+				a = t;
+
+				j++;
+			}
+			a = add( a, olda );
+			b = add( b, oldb );
+			c = add( c, oldc );
+			d = add( d, oldd );
+			e = add( e, olde );
+			i += 16;
+		}
+		return hex(a) + hex(b) + hex(c) + hex(d) + hex(e);
+	}
+
+	static function hex( num : Int32 ) : String {
+		var str = "";
+		var j = 7;
+		while( j >= 0 ) {
+			str += hex_chr.charAt( Int32.toInt( Int32.and((Int32.shr(num, j*4)), Int32.ofInt(0x0F)) ) );
+			j--;
+		}
+		return str;
+	}
+
+	/**
+		Convert a string to a sequence of 16-word blocks, stored as an array.
+		Append padding bits and the length, as described in the SHA1 standard.
+	 */
+	static function str2blks_SHA1( s :String ) : Array<Int32> {
+		var nblk = ((s.length + 8) >> 6) + 1;
+		var blks = new Array<Int32>();
+
+		for (i in 0...nblk*16)
+			blks[i] = Int32.ofInt(0);
+		for (i in 0...s.length){
+			var p = i >> 2;
+			var c = Int32.ofInt(s.charCodeAt(i));
+			blks[p] = Int32.or(blks[p], Int32.shl(c, (24 - (i % 4) * 8)));
+		}
+		var i = s.length;
+		var p = i >> 2;
+		blks[p] = Int32.or(blks[p], Int32.shl(Int32.ofInt(0x80), (24 - (i % 4) * 8)));
+		blks[nblk * 16 - 1] = Int32.ofInt(s.length * 8);
+		return blks;
+	}
+
+	/**
+		Add integers, wrapping at 2^32.
+	 */
+	static function add( x : Int32, y : Int32 ) : Int32 {
+		var lsw = Int32.add(Int32.and(x, Int32.ofInt(0xFFFF)), Int32.and(y, Int32.ofInt(0xFFFF)));
+		var msw = Int32.add(Int32.add(Int32.shr(x, 16), Int32.shr(y, 16)), Int32.shr(lsw, 16));
+		return Int32.or(Int32.shl(msw, 16), Int32.and(lsw, Int32.ofInt(0xFFFF)));
+	}
+
+	/**
+		Bitwise rotate a 32-bit number to the left
+	 */
+	static function rol( num : Int32, cnt : Int ) : Int32 {
+		return Int32.or(Int32.shl(num, cnt), Int32.ushr(num, (32 - cnt)));
+	}
+
+	/**
+		Perform the appropriate triplet combination function for the current iteration
+	*/
+	static function ft( t : Int32, b : Int32, c : Int32, d : Int32 ) : Int32 {
+		if (Int32.compare(t, Int32.ofInt(20)) <0) return Int32.or(Int32.and(b, c), Int32.and((Int32.complement(b)), d));
+		if (Int32.compare(t, Int32.ofInt(40)) <0) return Int32.xor(Int32.xor(b, c), d);
+		if (Int32.compare(t, Int32.ofInt(60)) <0) return Int32.or(Int32.or(Int32.and(b, c), Int32.and(b, d)), Int32.and(c, d));
+		return Int32.xor(Int32.xor(b, c), d);
+	}
+
+	/**
+		Determine the appropriate additive constant for the current iteration
+	*/
+	static function kt( t : Int32 ) : Int32 {
+		if (Int32.compare(t,Int32.ofInt(20)) < 0)
+			return newInt32(0x5A82, 0x7999);
+		if (Int32.compare(t,Int32.ofInt(40)) < 0)
+			return newInt32(0x6ed9, 0xeba1);
+		if (Int32.compare(t,Int32.ofInt(60)) < 0)
+			return newInt32(0x8f1b, 0xbcdc);
+		return newInt32(0xca62, 0xc1d6);
+	}
+
+}
+
+#end