[std] add unicode iterators for String

std/haxe/iterators/StringIteratorUnicode.hx

@@ -0,0 +1,69 @@
+/*
+ * Copyright (C)2005-2018 Haxe Foundation
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a
+ * copy of this software and associated documentation files (the "Software"),
+ * to deal in the Software without restriction, including without limitation
+ * the rights to use, copy, modify, merge, publish, distribute, sublicense,
+ * and/or sell copies of the Software, and to permit persons to whom the
+ * Software is furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in
+ * all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+ * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+ * DEALINGS IN THE SOFTWARE.
+ */
+package haxe.iterators;
+
+/**
+	This iterator can be used to iterate across strings in a cross-platform
+	way. It handles surrogate pairs on platforms that require it. On each
+	iteration, it returns the next character code.
+
+	Note that this has different semantics than a standard for-loop over the
+	String's length due to the fact that it deals with surrogate pairs.
+**/
+class StringIteratorUnicode {
+	var offset = 0;
+	var s:String;
+
+	/**
+		Create a new `StringIteratorUnicode` over String `s`.
+	**/
+	public inline function new(s:String) {
+		this.s = s;
+	}
+
+	/**
+		See `Iterator.hasNext`
+	**/
+	public inline function hasNext() {
+		return offset < s.length;
+	}
+
+	/**
+		See `Iterator.next`
+	**/
+	public inline function next() {
+		var c = StringTools.fastCodeAt(s, offset++);
+		#if utf16
+		if (c >= 0xD800 && c < 0xDBFF) {
+			c = ((c -0xD7C0) << 10) | (StringTools.fastCodeAt(s, offset++) & 0x3FF);
+		}
+		#end
+		return c;
+	}
+
+	/**
+		Convenience function which can be used as a static extension.
+	**/
+	static public inline function unicodeIterator(s:String) {
+		return new StringIteratorUnicode(s);
+	}
+}

std/haxe/iterators/StringKeyValueIteratorUnicode.hx

@@ -0,0 +1,72 @@
+/*
+ * Copyright (C)2005-2018 Haxe Foundation
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a
+ * copy of this software and associated documentation files (the "Software"),
+ * to deal in the Software without restriction, including without limitation
+ * the rights to use, copy, modify, merge, publish, distribute, sublicense,
+ * and/or sell copies of the Software, and to permit persons to whom the
+ * Software is furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in
+ * all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+ * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+ * DEALINGS IN THE SOFTWARE.
+ */
+package haxe.iterators;
+
+/**
+	This iterator can be used to iterate across strings in a cross-platform
+	way. It handles surrogate pairs on platforms that require it. On each
+	iteration, it returns the next character offset as key and the next
+	character code as value.
+
+	Note that in the general case, because of surrogate pairs, the key values
+	should not be used as offsets for various String API operations. For the
+	same reason, the last key value returned might be less than `s.length - 1`.
+**/
+class StringKeyValueIteratorUnicode {
+	var byteOffset = 0;
+	var charOffset = 0;
+	var s:String;
+
+	/**
+		Create a new `StringKeyValueIteratorUnicode` over String `s`.
+	**/
+	public inline function new(s:String) {
+		this.s = s;
+	}
+
+	/**
+		See `Iterator.hasNext`
+	**/
+	public inline function hasNext() {
+		return byteOffset < s.length;
+	}
+
+	/**
+		See `Iterator.next`
+	**/
+	public inline function next() {
+		var c = StringTools.fastCodeAt(s, byteOffset++);
+		#if utf16
+		if (c >= 0xD800 && c < 0xDBFF) {
+			c = ((c -0xD7C0) << 10) | (StringTools.fastCodeAt(s, byteOffset++) & 0x3FF);
+		}
+		#end
+		return { key: charOffset++, value: c };
+	}
+
+	/**
+		Convenience function which can be used as a static extension.
+	**/
+	static public inline function unicodeKeyValueIterator(s:String) {
+		return new StringKeyValueIteratorUnicode(s);
+	}
+}

tests/unit/src/unitstd/haxe/iterators/StringIteratorUnicode.unit.hx

@@ -0,0 +1,10 @@
+function traverse(s:String) {
+	var a = [];
+	for (code in new haxe.iterators.StringIteratorUnicode(s)) {
+		a.push(code);
+	}
+	return a;
+}
+
+traverse("abcde") == ["a".code, "b".code, "c".code, "d".code, "e".code];
+traverse("aa😂éé") == ["a".code, "a".code, "😂".code, "é".code, "é".code];

tests/unit/src/unitstd/haxe/iterators/StringKeyValueIteratorUnicode.unit.hx

@@ -0,0 +1,17 @@
+function traverse(s:String) {
+	var ak = [];
+	var av = [];
+	for (offset => code in new haxe.iterators.StringKeyValueIteratorUnicode(s)) {
+		ak.push(offset);
+		av.push(code);
+	}
+	return { k: ak, v: av };
+}
+
+var r = traverse("abcde");
+r.k == [0, 1, 2, 3, 4];
+r.v == ["a".code, "b".code, "c".code, "d".code, "e".code];
+
+var r = traverse("aa😂éé");
+r.k == [0, 1, 2, 3, 4];
+r.v == ["a".code, "a".code, "😂".code, "é".code, "é".code];