jfdctint.pas 11 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308
  1. {$IFNDEF FPC_DOTTEDUNITS}
  2. Unit JFDctInt;
  3. {$ENDIF FPC_DOTTEDUNITS}
  4. { This file contains a slow-but-accurate integer implementation of the
  5. forward DCT (Discrete Cosine Transform).
  6. A 2-D DCT can be done by 1-D DCT on each row followed by 1-D DCT
  7. on each column. Direct algorithms are also available, but they are
  8. much more complex and seem not to be any faster when reduced to code.
  9. This implementation is based on an algorithm described in
  10. C. Loeffler, A. Ligtenberg and G. Moschytz, "Practical Fast 1-D DCT
  11. Algorithms with 11 Multiplications", Proc. Int'l. Conf. on Acoustics,
  12. Speech, and Signal Processing 1989 (ICASSP '89), pp. 988-991.
  13. The primary algorithm described there uses 11 multiplies and 29 adds.
  14. We use their alternate method with 12 multiplies and 32 adds.
  15. The advantage of this method is that no data path contains more than one
  16. multiplication; this allows a very simple and accurate implementation in
  17. scaled fixed-point arithmetic, with a minimal number of shifts. }
  18. { Original : jfdctint.c ; Copyright (C) 1991-1996, Thomas G. Lane. }
  19. interface
  20. {$I jconfig.inc}
  21. {$IFDEF FPC_DOTTEDUNITS}
  22. uses
  23. System.Jpeg.Jmorecfg,
  24. System.Jpeg.Jinclude,
  25. System.Jpeg.Jutils,
  26. System.Jpeg.Jpeglib,
  27. System.Jpeg.Jdct; { Private declarations for DCT subsystem }
  28. {$ELSE FPC_DOTTEDUNITS}
  29. uses
  30. jmorecfg,
  31. jinclude,
  32. jutils,
  33. jpeglib,
  34. jdct; { Private declarations for DCT subsystem }
  35. {$ENDIF FPC_DOTTEDUNITS}
  36. { Perform the forward DCT on one block of samples. }
  37. {GLOBAL}
  38. procedure jpeg_fdct_islow (var data : array of DCTELEM);
  39. implementation
  40. { This module is specialized to the case DCTSIZE = 8. }
  41. {$ifndef DCTSIZE_IS_8}
  42. Sorry, this code only copes with 8x8 DCTs. { deliberate syntax err }
  43. {$endif}
  44. { The poop on this scaling stuff is as follows:
  45. Each 1-D DCT step produces outputs which are a factor of sqrt(N)
  46. larger than the true DCT outputs. The final outputs are therefore
  47. a factor of N larger than desired; since N=8 this can be cured by
  48. a simple right shift at the end of the algorithm. The advantage of
  49. this arrangement is that we save two multiplications per 1-D DCT,
  50. because the y0 and y4 outputs need not be divided by sqrt(N).
  51. In the IJG code, this factor of 8 is removed by the quantization step
  52. (in jcdctmgr.c), NOT in this module.
  53. We have to do addition and subtraction of the integer inputs, which
  54. is no problem, and multiplication by fractional constants, which is
  55. a problem to do in integer arithmetic. We multiply all the constants
  56. by CONST_SCALE and convert them to integer constants (thus retaining
  57. CONST_BITS bits of precision in the constants). After doing a
  58. multiplication we have to divide the product by CONST_SCALE, with proper
  59. rounding, to produce the correct output. This division can be done
  60. cheaply as a right shift of CONST_BITS bits. We postpone shifting
  61. as long as possible so that partial sums can be added together with
  62. full fractional precision.
  63. The outputs of the first pass are scaled up by PASS1_BITS bits so that
  64. they are represented to better-than-integral precision. These outputs
  65. require BITS_IN_JSAMPLE + PASS1_BITS + 3 bits; this fits in a 16-bit word
  66. with the recommended scaling. (For 12-bit sample data, the intermediate
  67. array is INT32 anyway.)
  68. To avoid overflow of the 32-bit intermediate results in pass 2, we must
  69. have BITS_IN_JSAMPLE + CONST_BITS + PASS1_BITS <= 26. Error analysis
  70. shows that the values given below are the most effective. }
  71. {$ifdef BITS_IN_JSAMPLE_IS_8}
  72. const
  73. CONST_BITS = 13;
  74. PASS1_BITS = 2;
  75. {$else}
  76. const
  77. CONST_BITS = 13;
  78. PASS1_BITS = 1; { lose a little precision to avoid overflow }
  79. {$endif}
  80. const
  81. CONST_SCALE = (INT32(1) shl CONST_BITS);
  82. const
  83. FIX_0_298631336 = INT32(Round(CONST_SCALE * 0.298631336)); {2446}
  84. FIX_0_390180644 = INT32(Round(CONST_SCALE * 0.390180644)); {3196}
  85. FIX_0_541196100 = INT32(Round(CONST_SCALE * 0.541196100)); {4433}
  86. FIX_0_765366865 = INT32(Round(CONST_SCALE * 0.765366865)); {6270}
  87. FIX_0_899976223 = INT32(Round(CONST_SCALE * 0.899976223)); {7373}
  88. FIX_1_175875602 = INT32(Round(CONST_SCALE * 1.175875602)); {9633}
  89. FIX_1_501321110 = INT32(Round(CONST_SCALE * 1.501321110)); {12299}
  90. FIX_1_847759065 = INT32(Round(CONST_SCALE * 1.847759065)); {15137}
  91. FIX_1_961570560 = INT32(Round(CONST_SCALE * 1.961570560)); {16069}
  92. FIX_2_053119869 = INT32(Round(CONST_SCALE * 2.053119869)); {16819}
  93. FIX_2_562915447 = INT32(Round(CONST_SCALE * 2.562915447)); {20995}
  94. FIX_3_072711026 = INT32(Round(CONST_SCALE * 3.072711026)); {25172}
  95. { Multiply an INT32 variable by an INT32 constant to yield an INT32 result.
  96. For 8-bit samples with the recommended scaling, all the variable
  97. and constant values involved are no more than 16 bits wide, so a
  98. 16x16->32 bit multiply can be used instead of a full 32x32 multiply.
  99. For 12-bit samples, a full 32-bit multiplication will be needed. }
  100. {$ifdef BITS_IN_JSAMPLE_IS_8}
  101. {MULTIPLY16C16(var,const)}
  102. function Multiply(X, Y: int): INT32;
  103. begin
  104. Multiply := int(X) * INT32(Y);
  105. end;
  106. {$else}
  107. function Multiply(X, Y: INT32): INT32;
  108. begin
  109. Multiply := X * Y;
  110. end;
  111. {$endif}
  112. { Descale and correctly round an INT32 value that's scaled by N bits.
  113. We assume RIGHT_SHIFT rounds towards minus infinity, so adding
  114. the fudge factor is correct for either sign of X. }
  115. function DESCALE(x : INT32; n : int) : INT32;
  116. var
  117. shift_temp : INT32;
  118. begin
  119. {$ifdef RIGHT_SHIFT_IS_UNSIGNED}
  120. shift_temp := x + (INT32(1) shl (n-1));
  121. if shift_temp < 0 then
  122. Descale := (shift_temp shr n) or ((not INT32(0)) shl (32-n))
  123. else
  124. Descale := (shift_temp shr n);
  125. {$else}
  126. Descale := (x + (INT32(1) shl (n-1)) shr n;
  127. {$endif}
  128. end;
  129. { Perform the forward DCT on one block of samples. }
  130. {GLOBAL}
  131. procedure jpeg_fdct_islow (var data : array of DCTELEM);
  132. type
  133. PWorkspace = ^TWorkspace;
  134. TWorkspace = array [0..DCTSIZE2-1] of DCTELEM;
  135. var
  136. tmp0, tmp1, tmp2, tmp3, tmp4, tmp5, tmp6, tmp7 : INT32;
  137. tmp10, tmp11, tmp12, tmp13 : INT32;
  138. z1, z2, z3, z4, z5 : INT32;
  139. dataptr : PWorkspace;
  140. ctr : int;
  141. {SHIFT_TEMPS}
  142. begin
  143. { Pass 1: process rows. }
  144. { Note results are scaled up by sqrt(8) compared to a true DCT; }
  145. { furthermore, we scale the results by 2**PASS1_BITS. }
  146. dataptr := PWorkspace(@data);
  147. for ctr := DCTSIZE-1 downto 0 do
  148. begin
  149. tmp0 := dataptr^[0] + dataptr^[7];
  150. tmp7 := dataptr^[0] - dataptr^[7];
  151. tmp1 := dataptr^[1] + dataptr^[6];
  152. tmp6 := dataptr^[1] - dataptr^[6];
  153. tmp2 := dataptr^[2] + dataptr^[5];
  154. tmp5 := dataptr^[2] - dataptr^[5];
  155. tmp3 := dataptr^[3] + dataptr^[4];
  156. tmp4 := dataptr^[3] - dataptr^[4];
  157. { Even part per LL&M figure 1 --- note that published figure is faulty;
  158. rotator "sqrt(2)*c1" should be "sqrt(2)*c6". }
  159. tmp10 := tmp0 + tmp3;
  160. tmp13 := tmp0 - tmp3;
  161. tmp11 := tmp1 + tmp2;
  162. tmp12 := tmp1 - tmp2;
  163. dataptr^[0] := DCTELEM ((tmp10 + tmp11) shl PASS1_BITS);
  164. dataptr^[4] := DCTELEM ((tmp10 - tmp11) shl PASS1_BITS);
  165. z1 := MULTIPLY(tmp12 + tmp13, FIX_0_541196100);
  166. dataptr^[2] := DCTELEM (DESCALE(z1 + MULTIPLY(tmp13, FIX_0_765366865),
  167. CONST_BITS-PASS1_BITS));
  168. dataptr^[6] := DCTELEM (DESCALE(z1 + MULTIPLY(tmp12, - FIX_1_847759065),
  169. CONST_BITS-PASS1_BITS));
  170. { Odd part per figure 8 --- note paper omits factor of sqrt(2).
  171. cK represents cos(K*pi/16).
  172. i0..i3 in the paper are tmp4..tmp7 here. }
  173. z1 := tmp4 + tmp7;
  174. z2 := tmp5 + tmp6;
  175. z3 := tmp4 + tmp6;
  176. z4 := tmp5 + tmp7;
  177. z5 := MULTIPLY(z3 + z4, FIX_1_175875602); { sqrt(2) * c3 }
  178. tmp4 := MULTIPLY(tmp4, FIX_0_298631336); { sqrt(2) * (-c1+c3+c5-c7) }
  179. tmp5 := MULTIPLY(tmp5, FIX_2_053119869); { sqrt(2) * ( c1+c3-c5+c7) }
  180. tmp6 := MULTIPLY(tmp6, FIX_3_072711026); { sqrt(2) * ( c1+c3+c5-c7) }
  181. tmp7 := MULTIPLY(tmp7, FIX_1_501321110); { sqrt(2) * ( c1+c3-c5-c7) }
  182. z1 := MULTIPLY(z1, - FIX_0_899976223); { sqrt(2) * (c7-c3) }
  183. z2 := MULTIPLY(z2, - FIX_2_562915447); { sqrt(2) * (-c1-c3) }
  184. z3 := MULTIPLY(z3, - FIX_1_961570560); { sqrt(2) * (-c3-c5) }
  185. z4 := MULTIPLY(z4, - FIX_0_390180644); { sqrt(2) * (c5-c3) }
  186. Inc(z3, z5);
  187. Inc(z4, z5);
  188. dataptr^[7] := DCTELEM(DESCALE(tmp4 + z1 + z3, CONST_BITS-PASS1_BITS));
  189. dataptr^[5] := DCTELEM(DESCALE(tmp5 + z2 + z4, CONST_BITS-PASS1_BITS));
  190. dataptr^[3] := DCTELEM(DESCALE(tmp6 + z2 + z3, CONST_BITS-PASS1_BITS));
  191. dataptr^[1] := DCTELEM(DESCALE(tmp7 + z1 + z4, CONST_BITS-PASS1_BITS));
  192. Inc(DCTELEMPTR(dataptr), DCTSIZE); { advance pointer to next row }
  193. end;
  194. { Pass 2: process columns.
  195. We remove the PASS1_BITS scaling, but leave the results scaled up
  196. by an overall factor of 8. }
  197. dataptr := PWorkspace(@data);
  198. for ctr := DCTSIZE-1 downto 0 do
  199. begin
  200. tmp0 := dataptr^[DCTSIZE*0] + dataptr^[DCTSIZE*7];
  201. tmp7 := dataptr^[DCTSIZE*0] - dataptr^[DCTSIZE*7];
  202. tmp1 := dataptr^[DCTSIZE*1] + dataptr^[DCTSIZE*6];
  203. tmp6 := dataptr^[DCTSIZE*1] - dataptr^[DCTSIZE*6];
  204. tmp2 := dataptr^[DCTSIZE*2] + dataptr^[DCTSIZE*5];
  205. tmp5 := dataptr^[DCTSIZE*2] - dataptr^[DCTSIZE*5];
  206. tmp3 := dataptr^[DCTSIZE*3] + dataptr^[DCTSIZE*4];
  207. tmp4 := dataptr^[DCTSIZE*3] - dataptr^[DCTSIZE*4];
  208. { Even part per LL&M figure 1 --- note that published figure is faulty;
  209. rotator "sqrt(2)*c1" should be "sqrt(2)*c6". }
  210. tmp10 := tmp0 + tmp3;
  211. tmp13 := tmp0 - tmp3;
  212. tmp11 := tmp1 + tmp2;
  213. tmp12 := tmp1 - tmp2;
  214. dataptr^[DCTSIZE*0] := DCTELEM (DESCALE(tmp10 + tmp11, PASS1_BITS));
  215. dataptr^[DCTSIZE*4] := DCTELEM (DESCALE(tmp10 - tmp11, PASS1_BITS));
  216. z1 := MULTIPLY(tmp12 + tmp13, FIX_0_541196100);
  217. dataptr^[DCTSIZE*2] := DCTELEM (DESCALE(z1 + MULTIPLY(tmp13, FIX_0_765366865),
  218. CONST_BITS+PASS1_BITS));
  219. dataptr^[DCTSIZE*6] := DCTELEM (DESCALE(z1 + MULTIPLY(tmp12, - FIX_1_847759065),
  220. CONST_BITS+PASS1_BITS));
  221. { Odd part per figure 8 --- note paper omits factor of sqrt(2).
  222. cK represents cos(K*pi/16).
  223. i0..i3 in the paper are tmp4..tmp7 here. }
  224. z1 := tmp4 + tmp7;
  225. z2 := tmp5 + tmp6;
  226. z3 := tmp4 + tmp6;
  227. z4 := tmp5 + tmp7;
  228. z5 := MULTIPLY(z3 + z4, FIX_1_175875602); { sqrt(2) * c3 }
  229. tmp4 := MULTIPLY(tmp4, FIX_0_298631336); { sqrt(2) * (-c1+c3+c5-c7) }
  230. tmp5 := MULTIPLY(tmp5, FIX_2_053119869); { sqrt(2) * ( c1+c3-c5+c7) }
  231. tmp6 := MULTIPLY(tmp6, FIX_3_072711026); { sqrt(2) * ( c1+c3+c5-c7) }
  232. tmp7 := MULTIPLY(tmp7, FIX_1_501321110); { sqrt(2) * ( c1+c3-c5-c7) }
  233. z1 := MULTIPLY(z1, - FIX_0_899976223); { sqrt(2) * (c7-c3) }
  234. z2 := MULTIPLY(z2, - FIX_2_562915447); { sqrt(2) * (-c1-c3) }
  235. z3 := MULTIPLY(z3, - FIX_1_961570560); { sqrt(2) * (-c3-c5) }
  236. z4 := MULTIPLY(z4, - FIX_0_390180644); { sqrt(2) * (c5-c3) }
  237. Inc(z3, z5);
  238. Inc(z4, z5);
  239. dataptr^[DCTSIZE*7] := DCTELEM (DESCALE(tmp4 + z1 + z3,
  240. CONST_BITS+PASS1_BITS));
  241. dataptr^[DCTSIZE*5] := DCTELEM (DESCALE(tmp5 + z2 + z4,
  242. CONST_BITS+PASS1_BITS));
  243. dataptr^[DCTSIZE*3] := DCTELEM (DESCALE(tmp6 + z2 + z3,
  244. CONST_BITS+PASS1_BITS));
  245. dataptr^[DCTSIZE*1] := DCTELEM (DESCALE(tmp7 + z1 + z4,
  246. CONST_BITS+PASS1_BITS));
  247. Inc(DCTELEMPTR(dataptr)); { advance pointer to next column }
  248. end;
  249. end;
  250. end.