Added new AllPagesExample.iss example script which shows all the wizard pages Setup may potentially display.

Examples/AllPagesExample.iss

@@ -0,0 +1,54 @@
+; -- AllPagesExample.iss --
+; Same as Example1.iss, but shows all the wizard pages Setup may potentially display
+
+; SEE THE DOCUMENTATION FOR DETAILS ON CREATING .ISS SCRIPT FILES!
+
+[Setup]
+AppName=My Program
+AppVersion=1.5
+WizardStyle=modern
+DefaultDirName={autopf}\My Program
+DefaultGroupName=My Program
+UninstallDisplayIcon={app}\MyProg.exe
+Compression=lzma2
+SolidCompression=yes
+OutputDir=userdocs:Inno Setup Examples Output
+
+DisableWelcomePage=no
+LicenseFile=license.txt
+#define Password 'password'
+Password={#Password}
+InfoBeforeFile=readme.txt
+UserInfoPage=yes
+PrivilegesRequired=lowest
+DisableDirPage=no
+DisableProgramGroupPage=no
+InfoAfterFile=readme.txt
+
+[Files]
+Source: "MyProg.exe"; DestDir: "{app}"
+Source: "MyProg.chm"; DestDir: "{app}"
+Source: "Readme.txt"; DestDir: "{app}"; Flags: isreadme
+
+[Icons]
+Name: "{group}\My Program"; Filename: "{app}\MyProg.exe"
+
+[Components]
+Name: "component"; Description: "Component";
+
+[Tasks]
+Name: "task"; Description: "Task";
+
+[Code]
+procedure InitializeWizard;
+begin
+  WizardForm.PasswordEdit.Text := '{#Password}';
+  
+  CreateCustomPage(wpSelectTasks, 'Empty Custom Page', 'This is an empty custom page.'); 
+end;
+
+function PrepareToInstall(var NeedsRestart: Boolean): String;
+begin
+  if MsgBox('Do you want to stop Setup at the Preparing To Install wizard page?', mbConfirmation, MB_YESNO) = IDYES then
+    Result := 'Stopped by user';
+end;

Examples/License.txt

@@ -0,0 +1 @@
+This is the LICENSE file for My Program.

ISHelp/isetup.xml

@@ -2858,6 +2858,8 @@ Shown by default, but can be disabled in some cases via <link topic="setup_disab
 
 </ul>
 
+<p>See the <i>AllPagesExample.iss</i> example script for an example which shows all these pages</p>.
+
 </body>
 </topic>
 

whatsnew.htm

@@ -120,7 +120,8 @@ For conditions of distribution and use, see <a href="http://www.jrsoftware.org/f
 </ul>
 <ul>
   <li>All documentation referring to the Power Users group has been removed: this group is not special anymore in Windows.</li>
-  <li>Documentation and examples improvements.</li>
+  <li>Added new <i>AllPagesExample.iss</i> example script which shows all the wizard pages Setup may potentially display.</li>
+  <li>Other documentation and examples improvements.</li>
   <li>Added official Icelandic translation.</li>
   <li>Delphi compiler updated from Delphi 2009 to Delphi 10.2 Tokyo. This change increases the size of Setup but decreases development, testing and deployment times. It also makes it easier to compile Inno Setup yourself using the free Delphi Community Edition.</li>
   <li>Minor tweaks.</li>