demo09.lpr 6.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222
  1. program demo09;
  2. {$I zglCustomConfig.cfg}
  3. {$IFDEF WINDOWS}
  4. {$R *.res}
  5. {$ENDIF}
  6. uses
  7. zglSpriteEngine,
  8. {$IFDEF USE_ZENGL_STATIC}
  9. zgl_main,
  10. zgl_screen,
  11. zgl_window,
  12. zgl_timers,
  13. zgl_keyboard,
  14. zgl_render_2d,
  15. zgl_fx,
  16. zgl_textures,
  17. zgl_textures_png,
  18. zgl_textures_jpg,
  19. zgl_sprite_2d,
  20. zgl_primitives_2d,
  21. zgl_font,
  22. zgl_text,
  23. zgl_math_2d,
  24. zgl_utils
  25. {$ELSE}
  26. zglHeader
  27. {$ENDIF}
  28. ;
  29. type
  30. CMiku = class(zglCSprite2D)
  31. protected
  32. FSpeed : zglTPoint2D;
  33. public
  34. procedure OnInit( _Texture : zglPTexture; _Layer : Integer ); override;
  35. procedure OnDraw; override;
  36. procedure OnProc; override;
  37. procedure OnFree; override;
  38. end;
  39. var
  40. dirRes : UTF8String {$IFNDEF MACOSX} = '../data/' {$ENDIF};
  41. fntMain : zglPFont;
  42. texLogo : zglPTexture;
  43. texMiku : zglPTexture;
  44. time : Integer;
  45. sengine2d : zglCSEngine2D;
  46. // Miku
  47. procedure CMiku.OnInit( _Texture : zglPTexture; _Layer : Integer );
  48. begin
  49. // RU: Укажем свою текстуру и слой для спрайта, заодно установятся стандартные параметры вроде ширины и высоты на основе данных о кадре в текстуре.
  50. // EN: Set own texture and layer for sprite, also standard parameters will be set automatically(like width and height from info about texture).
  51. inherited OnInit( texMiku, random( 10 ) );
  52. X := 800 + random( 800 );
  53. Y := random( 600 - 128 );
  54. // RU: Задаем скорость движения.
  55. // EN: Set the moving speed.
  56. FSpeed.X := -random( 10 ) / 5 - 0.5;
  57. FSpeed.Y := ( random( 10 ) - 5 ) / 5;
  58. end;
  59. procedure CMiku.OnDraw;
  60. begin
  61. // RU: Т.к. по сути эта процедура объявлена только для примера, то вызовем основной метод OnDraw класса zglCSprite2D.
  62. // EN: Because in fact, this procedure is declared only for example, so call to the main method OnDraw of class zglCSprite2D.
  63. inherited;
  64. end;
  65. procedure CMiku.OnProc;
  66. begin
  67. inherited;
  68. X := X + FSpeed.X;
  69. Y := Y + FSpeed.Y;
  70. Frame := Frame + ( abs( FSpeed.X ) + abs( FSpeed.Y ) ) / 25;
  71. if Frame > 8 Then
  72. Frame := 1;
  73. // RU: Если спрайт выходит за пределы по X, сразу же удаляем его.
  74. // EN: Delete the sprite if it goes beyond X.
  75. if X < -128 Then sengine2d.DelSprite( ID );
  76. // RU: Если спрайт выходит за пределы по Y, ставим его в очередь на удаление
  77. // EN: Add sprite to queue for delete if it goes beyond Y.
  78. if Y < -128 Then Kill := TRUE;
  79. if Y > 600 Then Kill := TRUE;
  80. end;
  81. procedure CMiku.OnFree;
  82. begin
  83. inherited;
  84. end;
  85. // RU: Добавить 100 спрайтов.
  86. // EN: Add 100 sprites.
  87. procedure AddMiku;
  88. var
  89. i, ID : Integer;
  90. begin
  91. for i := 1 to 100 do
  92. begin
  93. // RU: Запрашиваем у спрайтового менеджера новое "место" под спрайт :)
  94. // EN: Request a "place" for a new sprite :)
  95. ID := sengine2d.AddSprite();
  96. // RU: Создаем экземпляр спрайта CMiku. Аргументами конструктора являются сам менеджер и будущий ID для спрайта.
  97. // EN: Create a new CMiku. Constructor arguments must be current sprite engine and future ID for sprite.
  98. sengine2d.List[ ID ] := CMiku.Create( sengine2d, ID );
  99. end;
  100. end;
  101. // RU: Удалить 100 спрайтов.
  102. // EN: Delete 100 sprites.
  103. procedure DelMiku;
  104. var
  105. i : Integer;
  106. begin
  107. // RU: Удалим 100 спрайтов со случайным ID.
  108. // EN: Delete 100 sprites with random ID.
  109. for i := 1 to 100 do
  110. sengine2d.DelSprite( random( sengine2d.Count ) );
  111. end;
  112. procedure Init;
  113. var
  114. i : Integer;
  115. begin
  116. texLogo := tex_LoadFromFile( dirRes + 'zengl.png' );
  117. texMiku := tex_LoadFromFile( dirRes + 'miku.png' );
  118. tex_SetFrameSize( texMiku, 128, 128 );
  119. // RU: Создаем экземпляр zglCSEngine2D.
  120. // EN: Create zglCSEngine2D object.
  121. sengine2d := zglCSEngine2D.Create();
  122. // RU: Создадим 1000 спрайтов Miku-chan :)
  123. // EN: Create 1000 sprites of Miku-chan :)
  124. for i := 0 to 9 do
  125. AddMiku();
  126. fntMain := font_LoadFromFile( dirRes + 'font.zfi' );
  127. end;
  128. procedure Draw;
  129. begin
  130. batch2d_Begin();
  131. // RU: Рисуем все спрайты находящиеся в текущем спрайтовом менеджере.
  132. // EN: Render all sprites contained in current sprite engine.
  133. if time > 255 Then
  134. sengine2d.Draw();
  135. if time <= 255 Then
  136. ssprite2d_Draw( texLogo, 400 - 256, 300 - 128, 512, 256, 0, time )
  137. else
  138. if time < 510 Then
  139. begin
  140. pr2d_Rect( 0, 0, 800, 600, $000000, 510 - time, PR2D_FILL );
  141. ssprite2d_Draw( texLogo, 400 - 256, 300 - 128, 512, 256, 0, 510 - time );
  142. end;
  143. if time > 255 Then
  144. begin
  145. pr2d_Rect( 0, 0, 256, 64, $000000, 200, PR2D_FILL );
  146. text_Draw( fntMain, 0, 0, 'FPS: ' + u_IntToStr( zgl_Get( RENDER_FPS ) ) );
  147. text_Draw( fntMain, 0, 20, 'Sprites: ' + u_IntToStr( sengine2d.Count ) );
  148. text_Draw( fntMain, 0, 40, 'Up/Down - Add/Delete Miku :)' );
  149. end;
  150. batch2d_End();
  151. end;
  152. procedure Timer;
  153. begin
  154. INC( time, 2 );
  155. // RU: Выполняем обработку всех спрайтов в текущем спрайтовом менеджере.
  156. // EN: Process all sprites contained in current sprite engine.
  157. sengine2d.Proc();
  158. // RU: По нажатию пробела очистить все спрайты.
  159. // EN: Delete all sprites if space was pressed.
  160. if key_Press( K_SPACE ) Then sengine2d.ClearAll();
  161. if key_Press( K_UP ) Then AddMiku();
  162. if key_Press( K_DOWN ) Then DelMiku();
  163. if key_Press( K_ESCAPE ) Then zgl_Exit();
  164. key_ClearState();
  165. end;
  166. procedure Quit;
  167. begin
  168. // RU: Очищаем память от созданных спрайтов.
  169. // EN: Free allocated memory for sprites.
  170. sengine2d.Destroy();
  171. end;
  172. Begin
  173. {$IFNDEF USE_ZENGL_STATIC}
  174. if not zglLoad( libZenGL ) Then exit;
  175. {$ENDIF}
  176. randomize();
  177. timer_Add( @Timer, 16 );
  178. timer_Add( @AddMiku, 1000 );
  179. zgl_Reg( SYS_LOAD, @Init );
  180. zgl_Reg( SYS_DRAW, @Draw );
  181. zgl_Reg( SYS_EXIT, @Quit );
  182. wnd_SetCaption( '09 - Sprite Engine(Classes)' );
  183. wnd_ShowCursor( TRUE );
  184. scr_SetOptions( 800, 600, REFRESH_MAXIMUM, FALSE, FALSE );
  185. zgl_Init();
  186. End.