sdlchecks.cmake 40 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879808182838485868788899091929394959697989910010110210310410510610710810911011111211311411511611711811912012112212312412512612712812913013113213313413513613713813914014114214314414514614714814915015115215315415515615715815916016116216316416516616716816917017117217317417517617717817918018118218318418518618718818919019119219319419519619719819920020120220320420520620720820921021121221321421521621721821922022122222322422522622722822923023123223323423523623723823924024124224324424524624724824925025125225325425525625725825926026126226326426526626726826927027127227327427527627727827928028128228328428528628728828929029129229329429529629729829930030130230330430530630730830931031131231331431531631731831932032132232332432532632732832933033133233333433533633733833934034134234334434534634734834935035135235335435535635735835936036136236336436536636736836937037137237337437537637737837938038138238338438538638738838939039139239339439539639739839940040140240340440540640740840941041141241341441541641741841942042142242342442542642742842943043143243343443543643743843944044144244344444544644744844945045145245345445545645745845946046146246346446546646746846947047147247347447547647747847948048148248348448548648748848949049149249349449549649749849950050150250350450550650750850951051151251351451551651751851952052152252352452552652752852953053153253353453553653753853954054154254354454554654754854955055155255355455555655755855956056156256356456556656756856957057157257357457557657757857958058158258358458558658758858959059159259359459559659759859960060160260360460560660760860961061161261361461561661761861962062162262362462562662762862963063163263363463563663763863964064164264364464564664764864965065165265365465565665765865966066166266366466566666766866967067167267367467567667767867968068168268368468568668768868969069169269369469569669769869970070170270370470570670770870971071171271371471571671771871972072172272372472572672772872973073173273373473573673773873974074174274374474574674774874975075175275375475575675775875976076176276376476576676776876977077177277377477577677777877978078178278378478578678778878979079179279379479579679779879980080180280380480580680780880981081181281381481581681781881982082182282382482582682782882983083183283383483583683783883984084184284384484584684784884985085185285385485585685785885986086186286386486586686786886987087187287387487587687787887988088188288388488588688788888989089189289389489589689789889990090190290390490590690790890991091191291391491591691791891992092192292392492592692792892993093193293393493593693793893994094194294394494594694794894995095195295395495595695795895996096196296396496596696796896997097197297397497597697797897998098198298398498598698798898999099199299399499599699799899910001001100210031004100510061007100810091010101110121013101410151016101710181019102010211022102310241025102610271028102910301031103210331034103510361037103810391040104110421043104410451046104710481049105010511052105310541055105610571058105910601061106210631064106510661067106810691070107110721073107410751076107710781079108010811082108310841085108610871088108910901091109210931094109510961097109810991100110111021103110411051106110711081109111011111112111311141115111611171118111911201121112211231124112511261127112811291130113111321133113411351136113711381139114011411142114311441145114611471148114911501151115211531154115511561157115811591160116111621163116411651166116711681169117011711172117311741175117611771178117911801181118211831184118511861187118811891190
  1. include(CMakeParseArguments)
  2. include(${SDL3_SOURCE_DIR}/cmake/sdlfind.cmake)
  3. macro(FindLibraryAndSONAME _LIB)
  4. cmake_parse_arguments(FLAS "" "" "LIBDIRS" ${ARGN})
  5. string(TOUPPER ${_LIB} _UPPERLNAME)
  6. string(REGEX REPLACE "\\-" "_" _LNAME "${_UPPERLNAME}")
  7. find_library(${_LNAME}_LIB ${_LIB} PATHS ${FLAS_LIBDIRS})
  8. if(${_LNAME}_LIB MATCHES ".*\\${CMAKE_SHARED_LIBRARY_SUFFIX}.*" AND NOT ${_LNAME}_LIB MATCHES ".*\\${CMAKE_STATIC_LIBRARY_SUFFIX}.*")
  9. set(${_LNAME}_SHARED TRUE)
  10. else()
  11. set(${_LNAME}_SHARED FALSE)
  12. endif()
  13. if(${_LNAME}_LIB)
  14. # reduce the library name for shared linking
  15. get_filename_component(_LIB_REALPATH ${${_LNAME}_LIB} REALPATH) # resolves symlinks
  16. get_filename_component(_LIB_JUSTNAME ${_LIB_REALPATH} NAME)
  17. if(APPLE)
  18. string(REGEX REPLACE "(\\.[0-9]*)\\.[0-9\\.]*dylib$" "\\1.dylib" _LIB_REGEXD "${_LIB_JUSTNAME}")
  19. else()
  20. string(REGEX REPLACE "(\\.[0-9]*)\\.[0-9\\.]*$" "\\1" _LIB_REGEXD "${_LIB_JUSTNAME}")
  21. endif()
  22. get_filename_component(${_LNAME}_LIBDIR ${${_LNAME}_LIB} DIRECTORY)
  23. SET(_DEBUG_FindSONAME FALSE)
  24. if(_DEBUG_FindSONAME)
  25. message_warn("DYNLIB OUTPUTVAR: ${_LIB} ... ${_LNAME}_LIB")
  26. message_warn("DYNLIB ORIGINAL LIB: ${_LIB} ... ${${_LNAME}_LIB}")
  27. message_warn("DYNLIB REALPATH LIB: ${_LIB} ... ${_LIB_REALPATH}")
  28. message_warn("DYNLIB JUSTNAME LIB: ${_LIB} ... ${_LIB_JUSTNAME}")
  29. message_warn("DYNLIB REGEX'd LIB: ${_LIB} ... ${_LIB_REGEXD}")
  30. endif()
  31. message(STATUS "dynamic lib${_LIB} -> ${_LIB_REGEXD}")
  32. set(${_LNAME}_LIB_SONAME ${_LIB_REGEXD})
  33. endif()
  34. endmacro()
  35. macro(CheckDLOPEN)
  36. check_symbol_exists(dlopen "dlfcn.h" HAVE_DLOPEN_IN_LIBC)
  37. if(NOT HAVE_DLOPEN_IN_LIBC)
  38. cmake_push_check_state()
  39. list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
  40. check_symbol_exists(dlopen "dlfcn.h" HAVE_DLOPEN_IN_LIBDL)
  41. cmake_pop_check_state()
  42. if(HAVE_DLOPEN_IN_LIBDL)
  43. list(APPEND SDL_EXTRA_LIBS dl)
  44. endif()
  45. endif()
  46. if(HAVE_DLOPEN_IN_LIBC OR HAVE_DLOPEN_IN_LIBDL)
  47. set(HAVE_DLOPEN TRUE)
  48. endif()
  49. endmacro()
  50. macro(CheckO_CLOEXEC)
  51. check_c_source_compiles("
  52. #include <fcntl.h>
  53. int flag = O_CLOEXEC;
  54. int main(int argc, char **argv) { return 0; }" HAVE_O_CLOEXEC)
  55. endmacro()
  56. # Requires:
  57. # - n/a
  58. macro(CheckOSS)
  59. if(SDL_OSS)
  60. check_c_source_compiles("
  61. #include <sys/soundcard.h>
  62. int main(int argc, char **argv) { int arg = SNDCTL_DSP_SETFRAGMENT; return 0; }" HAVE_OSS_SYS_SOUNDCARD_H)
  63. if(HAVE_OSS_SYS_SOUNDCARD_H)
  64. set(HAVE_OSS TRUE)
  65. file(GLOB OSS_SOURCES ${SDL3_SOURCE_DIR}/src/audio/dsp/*.c)
  66. set(SDL_AUDIO_DRIVER_OSS 1)
  67. list(APPEND SOURCE_FILES ${OSS_SOURCES})
  68. if(NETBSD)
  69. list(APPEND SDL_EXTRA_LIBS ossaudio)
  70. endif()
  71. set(HAVE_SDL_AUDIO TRUE)
  72. endif()
  73. endif()
  74. endmacro()
  75. # Requires:
  76. # - n/a
  77. # Optional:
  78. # - SDL_ALSA_SHARED opt
  79. # - HAVE_SDL_LOADSO opt
  80. macro(CheckALSA)
  81. if(SDL_ALSA)
  82. sdlFindALSA()
  83. if(ALSA_FOUND)
  84. file(GLOB ALSA_SOURCES "${SDL3_SOURCE_DIR}/src/audio/alsa/*.c")
  85. list(APPEND SOURCE_FILES ${ALSA_SOURCES})
  86. set(SDL_AUDIO_DRIVER_ALSA 1)
  87. set(HAVE_ALSA TRUE)
  88. set(HAVE_ALSA_SHARED FALSE)
  89. if(SDL_ALSA_SHARED)
  90. if(HAVE_SDL_LOADSO)
  91. FindLibraryAndSONAME("asound")
  92. if(ASOUND_LIB AND ASOUND_SHARED)
  93. target_include_directories(sdl-build-options INTERFACE $<TARGET_PROPERTY:ALSA::ALSA,INTERFACE_INCLUDE_DIRECTORIES>)
  94. set(SDL_AUDIO_DRIVER_ALSA_DYNAMIC "\"${ASOUND_LIB_SONAME}\"")
  95. set(HAVE_ALSA_SHARED TRUE)
  96. else()
  97. message(WARNING "Unable to find asound shared object")
  98. endif()
  99. else()
  100. message(WARNING "You must have SDL_LoadObject() support for dynamic ALSA loading")
  101. endif()
  102. endif()
  103. if(NOT HAVE_ALSA_SHARED)
  104. list(APPEND SDL_CMAKE_DEPENDS ALSA::ALSA)
  105. list(APPEND SDL_PC_PRIVATE_REQUIRES alsa)
  106. endif()
  107. set(HAVE_SDL_AUDIO TRUE)
  108. endif()
  109. else()
  110. set(HAVE_ALSA FALSE)
  111. message(WARNING "Unable to find the alsa development library")
  112. endif()
  113. endmacro()
  114. # Requires:
  115. # - PkgCheckModules
  116. # Optional:
  117. # - SDL_PIPEWIRE_SHARED opt
  118. # - HAVE_SDL_LOADSO opt
  119. macro(CheckPipewire)
  120. if(SDL_PIPEWIRE)
  121. pkg_check_modules(PKG_PIPEWIRE libpipewire-0.3>=0.3.20)
  122. if(PKG_PIPEWIRE_FOUND)
  123. set(HAVE_PIPEWIRE TRUE)
  124. file(GLOB PIPEWIRE_SOURCES ${SDL3_SOURCE_DIR}/src/audio/pipewire/*.c)
  125. list(APPEND SOURCE_FILES ${PIPEWIRE_SOURCES})
  126. set(SDL_AUDIO_DRIVER_PIPEWIRE 1)
  127. target_compile_options(sdl-build-options INTERFACE ${PKG_PIPEWIRE_CFLAGS})
  128. if(SDL_PIPEWIRE_SHARED AND NOT HAVE_SDL_LOADSO)
  129. message_warn("You must have SDL_LoadObject() support for dynamic Pipewire loading")
  130. endif()
  131. FindLibraryAndSONAME("pipewire-0.3" LIBDIRS ${PKG_PIPEWIRE_LIBRARY_DIRS})
  132. if(SDL_PIPEWIRE_SHARED AND PIPEWIRE_0.3_LIB AND HAVE_SDL_LOADSO)
  133. set(SDL_AUDIO_DRIVER_PIPEWIRE_DYNAMIC "\"${PIPEWIRE_0.3_LIB_SONAME}\"")
  134. set(HAVE_PIPEWIRE_SHARED TRUE)
  135. else()
  136. list(APPEND SDL_EXTRA_LDFLAGS ${PKG_PIPEWIRE_LDFLAGS})
  137. endif()
  138. set(HAVE_SDL_AUDIO TRUE)
  139. endif()
  140. endif()
  141. endmacro()
  142. # Requires:
  143. # - PkgCheckModules
  144. # Optional:
  145. # - SDL_PULSEAUDIO_SHARED opt
  146. # - HAVE_SDL_LOADSO opt
  147. macro(CheckPulseAudio)
  148. if(SDL_PULSEAUDIO)
  149. pkg_check_modules(PKG_PULSEAUDIO libpulse-simple)
  150. if(PKG_PULSEAUDIO_FOUND)
  151. set(HAVE_PULSEAUDIO TRUE)
  152. file(GLOB PULSEAUDIO_SOURCES ${SDL3_SOURCE_DIR}/src/audio/pulseaudio/*.c)
  153. list(APPEND SOURCE_FILES ${PULSEAUDIO_SOURCES})
  154. set(SDL_AUDIO_DRIVER_PULSEAUDIO 1)
  155. target_compile_options(sdl-build-options INTERFACE ${PKG_PULSEAUDIO_CFLAGS})
  156. if(SDL_PULSEAUDIO_SHARED AND NOT HAVE_SDL_LOADSO)
  157. message_warn("You must have SDL_LoadObject() support for dynamic PulseAudio loading")
  158. endif()
  159. FindLibraryAndSONAME("pulse-simple" LIBDIRS ${PKG_PULSEAUDIO_LIBRARY_DIRS})
  160. if(SDL_PULSEAUDIO_SHARED AND PULSE_SIMPLE_LIB AND HAVE_SDL_LOADSO)
  161. set(SDL_AUDIO_DRIVER_PULSEAUDIO_DYNAMIC "\"${PULSE_SIMPLE_LIB_SONAME}\"")
  162. set(HAVE_PULSEAUDIO_SHARED TRUE)
  163. else()
  164. list(APPEND SDL_EXTRA_LDFLAGS ${PKG_PULSEAUDIO_LDFLAGS})
  165. endif()
  166. set(HAVE_SDL_AUDIO TRUE)
  167. endif()
  168. endif()
  169. endmacro()
  170. # Requires:
  171. # - PkgCheckModules
  172. # Optional:
  173. # - SDL_JACK_SHARED opt
  174. # - HAVE_SDL_LOADSO opt
  175. macro(CheckJACK)
  176. if(SDL_JACK)
  177. pkg_check_modules(PKG_JACK jack)
  178. if(PKG_JACK_FOUND)
  179. set(HAVE_JACK TRUE)
  180. file(GLOB JACK_SOURCES ${SDL3_SOURCE_DIR}/src/audio/jack/*.c)
  181. list(APPEND SOURCE_FILES ${JACK_SOURCES})
  182. set(SDL_AUDIO_DRIVER_JACK 1)
  183. target_compile_options(sdl-build-options INTERFACE ${PKG_JACK_CFLAGS})
  184. if(SDL_JACK_SHARED AND NOT HAVE_SDL_LOADSO)
  185. message_warn("You must have SDL_LoadObject() support for dynamic JACK audio loading")
  186. endif()
  187. FindLibraryAndSONAME("jack" LIBDIRS ${PKG_JACK_LIBRARY_DIRS})
  188. if(SDL_JACK_SHARED AND JACK_LIB AND HAVE_SDL_LOADSO)
  189. set(SDL_AUDIO_DRIVER_JACK_DYNAMIC "\"${JACK_LIB_SONAME}\"")
  190. set(HAVE_JACK_SHARED TRUE)
  191. else()
  192. list(APPEND SDL_EXTRA_LDFLAGS ${PKG_JACK_LDFLAGS})
  193. endif()
  194. set(HAVE_SDL_AUDIO TRUE)
  195. endif()
  196. endif()
  197. endmacro()
  198. # Requires:
  199. # - PkgCheckModules
  200. # Optional:
  201. # - SDL_SNDIO_SHARED opt
  202. # - HAVE_SDL_LOADSO opt
  203. macro(CheckSNDIO)
  204. if(SDL_SNDIO)
  205. pkg_check_modules(PKG_SNDIO sndio)
  206. if(PKG_SNDIO_FOUND)
  207. set(HAVE_SNDIO TRUE)
  208. file(GLOB SNDIO_SOURCES ${SDL3_SOURCE_DIR}/src/audio/sndio/*.c)
  209. list(APPEND SOURCE_FILES ${SNDIO_SOURCES})
  210. set(SDL_AUDIO_DRIVER_SNDIO 1)
  211. target_compile_options(sdl-build-options INTERFACE ${PKG_SNDIO_CFLAGS})
  212. if(SDL_SNDIO_SHARED AND NOT HAVE_SDL_LOADSO)
  213. message_warn("You must have SDL_LoadObject() support for dynamic sndio loading")
  214. endif()
  215. FindLibraryAndSONAME("sndio" LIBDIRS ${PKG_SNDIO_LIBRARY_DIRS})
  216. if(SDL_SNDIO_SHARED AND SNDIO_LIB AND HAVE_SDL_LOADSO)
  217. set(SDL_AUDIO_DRIVER_SNDIO_DYNAMIC "\"${SNDIO_LIB_SONAME}\"")
  218. set(HAVE_SNDIO_SHARED TRUE)
  219. else()
  220. list(APPEND SDL_EXTRA_LIBS ${PKG_SNDIO_LDFLAGS})
  221. endif()
  222. set(HAVE_SDL_AUDIO TRUE)
  223. endif()
  224. endif()
  225. endmacro()
  226. # Requires:
  227. # - SDL_LIBSAMPLERATE
  228. # Optional:
  229. # - SDL_LIBSAMPLERATE_SHARED opt
  230. # - HAVE_SDL_LOADSO opt
  231. macro(CheckLibSampleRate)
  232. if(SDL_LIBSAMPLERATE)
  233. find_package(SampleRate QUIET)
  234. if(SampleRate_FOUND AND TARGET SampleRate::samplerate)
  235. set(HAVE_LIBSAMPLERATE TRUE)
  236. set(HAVE_LIBSAMPLERATE_H TRUE)
  237. if(SDL_LIBSAMPLERATE_SHARED)
  238. target_include_directories(sdl-build-options INTERFACE $<TARGET_PROPERTY:SampleRate::samplerate,INTERFACE_INCLUDE_DIRECTORIES>)
  239. if(NOT HAVE_SDL_LOADSO)
  240. message_warn("You must have SDL_LoadObject() support for dynamic libsamplerate loading")
  241. else()
  242. get_property(_samplerate_type TARGET SampleRate::samplerate PROPERTY TYPE)
  243. if(_samplerate_type STREQUAL "SHARED_LIBRARY")
  244. set(HAVE_LIBSAMPLERATE_SHARED TRUE)
  245. if(WIN32)
  246. set(SDL_LIBSAMPLERATE_DYNAMIC "\"$<TARGET_FILE_NAME:SampleRate::samplerate>\"")
  247. else()
  248. set(SDL_LIBSAMPLERATE_DYNAMIC "\"$<TARGET_SONAME_FILE_NAME:SampleRate::samplerate>\"")
  249. endif()
  250. endif()
  251. endif()
  252. else()
  253. target_link_libraries(sdl-build-options INTERFACE SampleRate::samplerate)
  254. endif()
  255. else()
  256. check_include_file(samplerate.h HAVE_LIBSAMPLERATE_H)
  257. if(HAVE_LIBSAMPLERATE_H)
  258. set(HAVE_LIBSAMPLERATE TRUE)
  259. if(SDL_LIBSAMPLERATE_SHARED AND NOT HAVE_SDL_LOADSO)
  260. message_warn("You must have SDL_LoadObject() support for dynamic libsamplerate loading")
  261. endif()
  262. FindLibraryAndSONAME("samplerate")
  263. if(SDL_LIBSAMPLERATE_SHARED AND SAMPLERATE_LIB AND HAVE_SDL_LOADSO)
  264. set(SDL_LIBSAMPLERATE_DYNAMIC "\"${SAMPLERATE_LIB_SONAME}\"")
  265. set(HAVE_LIBSAMPLERATE_SHARED TRUE)
  266. else()
  267. list(APPEND SDL_EXTRA_LIBS samplerate)
  268. endif()
  269. endif()
  270. endif()
  271. endif()
  272. endmacro()
  273. # Requires:
  274. # - n/a
  275. # Optional:
  276. # - SDL_X11_SHARED opt
  277. # - HAVE_SDL_LOADSO opt
  278. macro(CheckX11)
  279. cmake_push_check_state()
  280. if(SDL_X11)
  281. foreach(_LIB X11 Xext Xcursor Xi Xfixes Xrandr Xrender Xss)
  282. FindLibraryAndSONAME("${_LIB}")
  283. endforeach()
  284. set(X11_dirs)
  285. find_path(X_INCLUDEDIR
  286. NAMES X11/Xlib.h
  287. PATHS
  288. /usr/pkg/xorg/include
  289. /usr/X11R6/include
  290. /usr/X11R7/include
  291. /usr/local/include/X11
  292. /usr/include/X11
  293. /usr/openwin/include
  294. /usr/openwin/share/include
  295. /opt/graphics/OpenGL/include
  296. /opt/X11/include
  297. )
  298. if(X_INCLUDEDIR)
  299. target_include_directories(sdl-build-options INTERFACE "${X_INCLUDEDIR}")
  300. list(APPEND CMAKE_REQUIRED_INCLUDES ${X_INCLUDEDIR})
  301. endif()
  302. find_file(HAVE_XCURSOR_H NAMES "X11/Xcursor/Xcursor.h" HINTS "${X_INCLUDEDIR}")
  303. find_file(HAVE_XINPUT2_H NAMES "X11/extensions/XInput2.h" HINTS "${X_INCLUDEDIR}")
  304. find_file(HAVE_XRANDR_H NAMES "X11/extensions/Xrandr.h" HINTS "${X_INCLUDEDIR}")
  305. find_file(HAVE_XFIXES_H_ NAMES "X11/extensions/Xfixes.h" HINTS "${X_INCLUDEDIR}")
  306. find_file(HAVE_XRENDER_H NAMES "X11/extensions/Xrender.h" HINTS "${X_INCLUDEDIR}")
  307. find_file(HAVE_XSS_H NAMES "X11/extensions/scrnsaver.h" HINTS "${X_INCLUDEDIR}")
  308. find_file(HAVE_XSHAPE_H NAMES "X11/extensions/shape.h" HINTS "${X_INCLUDEDIR}")
  309. find_file(HAVE_XDBE_H NAMES "X11/extensions/Xdbe.h" HINTS "${X_INCLUDEDIR}")
  310. find_file(HAVE_XEXT_H NAMES "X11/extensions/Xext.h" HINTS "${X_INCLUDEDIR}")
  311. if(X11_LIB)
  312. if(NOT HAVE_XEXT_H)
  313. message_error("Missing Xext.h, maybe you need to install the libxext-dev package?")
  314. endif()
  315. set(HAVE_X11 TRUE)
  316. set(HAVE_SDL_VIDEO TRUE)
  317. file(GLOB X11_SOURCES ${SDL3_SOURCE_DIR}/src/video/x11/*.c)
  318. list(APPEND SOURCE_FILES ${X11_SOURCES})
  319. set(SDL_VIDEO_DRIVER_X11 1)
  320. # !!! FIXME: why is this disabled for Apple?
  321. if(APPLE)
  322. set(SDL_X11_SHARED OFF)
  323. endif()
  324. check_symbol_exists(shmat "sys/shm.h" HAVE_SHMAT_IN_LIBC)
  325. if(NOT HAVE_SHMAT_IN_LIBC)
  326. check_library_exists(ipc shmat "" HAVE_SHMAT_IN_LIBIPC)
  327. if(HAVE_SHMAT_IN_LIBIPC)
  328. list(APPEND SDL_EXTRA_LIBS ipc)
  329. endif()
  330. if(NOT HAVE_SHMAT_IN_LIBIPC)
  331. target_compile_definitions(sdl-build-options INTERFACE "NO_SHARED_MEMORY")
  332. endif()
  333. endif()
  334. if(SDL_X11_SHARED)
  335. if(NOT HAVE_SDL_LOADSO)
  336. message_warn("You must have SDL_LoadObject() support for dynamic X11 loading")
  337. set(HAVE_X11_SHARED FALSE)
  338. else()
  339. set(HAVE_X11_SHARED TRUE)
  340. endif()
  341. if(X11_LIB)
  342. if(HAVE_X11_SHARED)
  343. set(SDL_VIDEO_DRIVER_X11_DYNAMIC "\"${X11_LIB_SONAME}\"")
  344. else()
  345. list(APPEND SDL_EXTRA_LDFLAGS "-L${X11_LIBDIR}")
  346. list(APPEND SDL_EXTRA_LIBS X11)
  347. endif()
  348. endif()
  349. if(XEXT_LIB)
  350. if(HAVE_X11_SHARED)
  351. set(SDL_VIDEO_DRIVER_X11_DYNAMIC_XEXT "\"${XEXT_LIB_SONAME}\"")
  352. else()
  353. list(APPEND SDL_EXTRA_LDFLAGS "-L${XEXT_LIBDIR}")
  354. list(APPEND SDL_EXTRA_LIBS Xext)
  355. endif()
  356. endif()
  357. else()
  358. list(APPEND SDL_EXTRA_LDFLAGS "-L${X11_LIBDIR}" "-L${XEXT_LIBDIR}")
  359. list(APPEND SDL_EXTRA_LIBS X11 Xext)
  360. endif()
  361. list(APPEND CMAKE_REQUIRED_LIBRARIES ${X11_LIB})
  362. check_c_source_compiles("
  363. #include <X11/Xlib.h>
  364. int main(int argc, char **argv) {
  365. Display *display;
  366. XEvent event;
  367. XGenericEventCookie *cookie = &event.xcookie;
  368. XNextEvent(display, &event);
  369. XGetEventData(display, cookie);
  370. XFreeEventData(display, cookie);
  371. return 0; }" HAVE_XGENERICEVENT)
  372. if(HAVE_XGENERICEVENT)
  373. set(SDL_VIDEO_DRIVER_X11_SUPPORTS_GENERIC_EVENTS 1)
  374. endif()
  375. check_symbol_exists(XkbKeycodeToKeysym "X11/Xlib.h;X11/XKBlib.h" SDL_VIDEO_DRIVER_X11_HAS_XKBKEYCODETOKEYSYM)
  376. if(SDL_X11_XCURSOR AND HAVE_XCURSOR_H AND XCURSOR_LIB)
  377. set(HAVE_X11_XCURSOR TRUE)
  378. if(HAVE_X11_SHARED)
  379. set(SDL_VIDEO_DRIVER_X11_DYNAMIC_XCURSOR "\"${XCURSOR_LIB_SONAME}\"")
  380. else()
  381. list(APPEND SDL_EXTRA_LDFLAGS "-L${XCURSOR_LIBDIR}")
  382. list(APPEND SDL_EXTRA_LIBS Xcursor)
  383. endif()
  384. set(SDL_VIDEO_DRIVER_X11_XCURSOR 1)
  385. endif()
  386. if(SDL_X11_XDBE AND HAVE_XDBE_H)
  387. set(HAVE_X11_XDBE TRUE)
  388. set(SDL_VIDEO_DRIVER_X11_XDBE 1)
  389. endif()
  390. if(SDL_X11_XINPUT AND HAVE_XINPUT2_H AND XI_LIB)
  391. set(HAVE_X11_XINPUT TRUE)
  392. if(HAVE_X11_SHARED)
  393. set(SDL_VIDEO_DRIVER_X11_DYNAMIC_XINPUT2 "\"${XI_LIB_SONAME}\"")
  394. else()
  395. list(APPEND SDL_EXTRA_LDFLAGS "-L${XI_LIBDIR}")
  396. list(APPEND SDL_EXTRA_LIBS Xi)
  397. endif()
  398. set(SDL_VIDEO_DRIVER_X11_XINPUT2 1)
  399. # Check for multitouch
  400. check_c_source_compiles("
  401. #include <X11/Xlib.h>
  402. #include <X11/Xproto.h>
  403. #include <X11/extensions/XInput2.h>
  404. int event_type = XI_TouchBegin;
  405. XITouchClassInfo *t;
  406. Status XIAllowTouchEvents(Display *a,int b,unsigned int c,Window d,int f) {
  407. return (Status)0;
  408. }
  409. int main(int argc, char **argv) { return 0; }" HAVE_XINPUT2_MULTITOUCH)
  410. if(HAVE_XINPUT2_MULTITOUCH)
  411. set(SDL_VIDEO_DRIVER_X11_XINPUT2_SUPPORTS_MULTITOUCH 1)
  412. endif()
  413. endif()
  414. # check along with XInput2.h because we use Xfixes with XIBarrierReleasePointer
  415. if(SDL_X11_XFIXES AND HAVE_XFIXES_H_ AND HAVE_XINPUT2_H)
  416. check_c_source_compiles("
  417. #include <X11/Xlib.h>
  418. #include <X11/Xproto.h>
  419. #include <X11/extensions/XInput2.h>
  420. #include <X11/extensions/Xfixes.h>
  421. BarrierEventID b;
  422. int main(int argc, char **argv) { return 0; }" HAVE_XFIXES_H)
  423. endif()
  424. if(SDL_X11_XFIXES AND HAVE_XFIXES_H AND HAVE_XINPUT2_H AND XFIXES_LIB)
  425. if(HAVE_X11_SHARED)
  426. set(SDL_VIDEO_DRIVER_X11_DYNAMIC_XFIXES "\"${XFIXES_LIB_SONAME}\"")
  427. else()
  428. list(APPEND SDL_EXTRA_LDFLAGS "-L${XFIXES_LIBDIR}")
  429. list(APPEND SDL_EXTRA_LIBS Xfixes)
  430. endif()
  431. set(SDL_VIDEO_DRIVER_X11_XFIXES 1)
  432. set(HAVE_X11_XFIXES TRUE)
  433. endif()
  434. if(SDL_X11_XRANDR AND HAVE_XRANDR_H AND XRANDR_LIB)
  435. if(HAVE_X11_SHARED)
  436. set(SDL_VIDEO_DRIVER_X11_DYNAMIC_XRANDR "\"${XRANDR_LIB_SONAME}\"")
  437. else()
  438. list(APPEND SDL_EXTRA_LDFLAGS "-L${XRANDR_LIBDIR}")
  439. list(APPEND SDL_EXTRA_LIBS Xrandr)
  440. endif()
  441. set(SDL_VIDEO_DRIVER_X11_XRANDR 1)
  442. set(HAVE_X11_XRANDR TRUE)
  443. endif()
  444. if(SDL_X11_XSCRNSAVER AND HAVE_XSS_H AND XSS_LIB)
  445. if(HAVE_X11_SHARED)
  446. set(SDL_VIDEO_DRIVER_X11_DYNAMIC_XSS "\"${XSS_LIB_SONAME}\"")
  447. else()
  448. list(APPEND SDL_EXTRA_LDFLAGS "-L${XSS_LIBDIR}")
  449. list(APPEND SDL_EXTRA_LIBS Xss)
  450. endif()
  451. set(SDL_VIDEO_DRIVER_X11_XSCRNSAVER 1)
  452. set(HAVE_X11_XSCRNSAVER TRUE)
  453. endif()
  454. if(SDL_X11_XSHAPE AND HAVE_XSHAPE_H)
  455. set(SDL_VIDEO_DRIVER_X11_XSHAPE 1)
  456. set(HAVE_X11_XSHAPE TRUE)
  457. endif()
  458. endif()
  459. endif()
  460. if(NOT HAVE_X11)
  461. # Prevent Mesa from including X11 headers
  462. target_compile_definitions(sdl-build-options INTERFACE "MESA_EGL_NO_X11_HEADERS" "EGL_NO_X11")
  463. endif()
  464. cmake_pop_check_state()
  465. endmacro()
  466. macro(WaylandProtocolGen _SCANNER _CODE_MODE _XML _PROTL)
  467. set(_WAYLAND_PROT_C_CODE "${CMAKE_CURRENT_BINARY_DIR}/wayland-generated-protocols/${_PROTL}-protocol.c")
  468. set(_WAYLAND_PROT_H_CODE "${CMAKE_CURRENT_BINARY_DIR}/wayland-generated-protocols/${_PROTL}-client-protocol.h")
  469. add_custom_command(
  470. OUTPUT "${_WAYLAND_PROT_H_CODE}"
  471. DEPENDS "${_XML}"
  472. COMMAND "${_SCANNER}"
  473. ARGS client-header "${_XML}" "${_WAYLAND_PROT_H_CODE}"
  474. )
  475. add_custom_command(
  476. OUTPUT "${_WAYLAND_PROT_C_CODE}"
  477. DEPENDS "${_WAYLAND_PROT_H_CODE}"
  478. COMMAND "${_SCANNER}"
  479. ARGS "${_CODE_MODE}" "${_XML}" "${_WAYLAND_PROT_C_CODE}"
  480. )
  481. list(APPEND SDL_GENERATED_HEADERS "${_WAYLAND_PROT_H_CODE}")
  482. list(APPEND SOURCE_FILES "${_WAYLAND_PROT_C_CODE}")
  483. endmacro()
  484. # Requires:
  485. # - EGL
  486. # - PkgCheckModules
  487. # Optional:
  488. # - SDL_WAYLAND_SHARED opt
  489. # - HAVE_SDL_LOADSO opt
  490. macro(CheckWayland)
  491. if(SDL_WAYLAND)
  492. set(WAYLAND_FOUND FALSE)
  493. pkg_check_modules(PKG_WAYLAND "wayland-client>=1.18" wayland-egl wayland-cursor egl "xkbcommon>=0.5.0")
  494. if(PKG_WAYLAND_FOUND)
  495. set(WAYLAND_FOUND TRUE)
  496. find_program(WAYLAND_SCANNER NAMES wayland-scanner REQUIRED)
  497. execute_process(
  498. COMMAND ${WAYLAND_SCANNER} --version
  499. RESULT_VARIABLE WAYLAND_SCANNER_VERSION_RC
  500. ERROR_VARIABLE WAYLAND_SCANNER_VERSION
  501. ERROR_STRIP_TRAILING_WHITESPACE
  502. )
  503. if(NOT WAYLAND_SCANNER_VERSION_RC EQUAL 0)
  504. message(FATAL "Failed to get wayland-scanner version")
  505. set(WAYLAND_FOUND FALSE)
  506. endif()
  507. string(REPLACE "wayland-scanner " "" WAYLAND_SCANNER_VERSION ${WAYLAND_SCANNER_VERSION})
  508. string(COMPARE LESS ${WAYLAND_SCANNER_VERSION} "1.15.0" WAYLAND_SCANNER_PRE_1_15)
  509. if(WAYLAND_SCANNER_PRE_1_15)
  510. set(WAYLAND_SCANNER_CODE_MODE "code")
  511. else()
  512. set(WAYLAND_SCANNER_CODE_MODE "private-code")
  513. endif()
  514. endif()
  515. if(WAYLAND_FOUND)
  516. target_link_directories(sdl-build-options INTERFACE ${PKG_WAYLAND_LIBRARY_DIRS})
  517. target_include_directories(sdl-build-options INTERFACE ${PKG_WAYLAND_INCLUDE_DIRS})
  518. set(HAVE_WAYLAND TRUE)
  519. set(HAVE_SDL_VIDEO TRUE)
  520. file(GLOB WAYLAND_SOURCES ${SDL3_SOURCE_DIR}/src/video/wayland/*.c)
  521. list(APPEND SOURCE_FILES ${WAYLAND_SOURCES})
  522. # We have to generate some protocol interface code for some unstable Wayland features.
  523. file(MAKE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/wayland-generated-protocols")
  524. target_include_directories(sdl-build-options INTERFACE "${CMAKE_CURRENT_BINARY_DIR}/wayland-generated-protocols")
  525. file(GLOB WAYLAND_PROTOCOLS_XML RELATIVE "${SDL3_SOURCE_DIR}/wayland-protocols/" "${SDL3_SOURCE_DIR}/wayland-protocols/*.xml")
  526. foreach(_XML ${WAYLAND_PROTOCOLS_XML})
  527. string(REGEX REPLACE "\\.xml$" "" _PROTL "${_XML}")
  528. WaylandProtocolGen("${WAYLAND_SCANNER}" "${WAYLAND_SCANNER_CODE_MODE}" "${SDL3_SOURCE_DIR}/wayland-protocols/${_XML}" "${_PROTL}")
  529. endforeach()
  530. if(SDL_WAYLAND_QT_TOUCH)
  531. set(HAVE_WAYLAND_QT_TOUCH TRUE)
  532. set(SDL_VIDEO_DRIVER_WAYLAND_QT_TOUCH 1)
  533. endif()
  534. if(SDL_WAYLAND_SHARED AND NOT HAVE_SDL_LOADSO)
  535. message_warn("You must have SDL_LoadObject() support for dynamic Wayland loading")
  536. endif()
  537. FindLibraryAndSONAME(wayland-client LIBDIRS ${PKG_WAYLAND_LIBRARY_DIRS})
  538. FindLibraryAndSONAME(wayland-egl LIBDIRS ${PKG_WAYLAND_LIBRARY_DIRS})
  539. FindLibraryAndSONAME(wayland-cursor LIBDIRS ${PKG_WAYLAND_LIBRARY_DIRS})
  540. FindLibraryAndSONAME(xkbcommon LIBDIRS ${PKG_WAYLAND_LIBRARY_DIRS})
  541. if(SDL_WAYLAND_SHARED AND WAYLAND_CLIENT_LIB AND WAYLAND_EGL_LIB AND WAYLAND_CURSOR_LIB AND XKBCOMMON_LIB AND HAVE_SDL_LOADSO)
  542. set(SDL_VIDEO_DRIVER_WAYLAND_DYNAMIC "\"${WAYLAND_CLIENT_LIB_SONAME}\"")
  543. set(SDL_VIDEO_DRIVER_WAYLAND_DYNAMIC_EGL "\"${WAYLAND_EGL_LIB_SONAME}\"")
  544. set(SDL_VIDEO_DRIVER_WAYLAND_DYNAMIC_CURSOR "\"${WAYLAND_CURSOR_LIB_SONAME}\"")
  545. set(SDL_VIDEO_DRIVER_WAYLAND_DYNAMIC_XKBCOMMON "\"${XKBCOMMON_LIB_SONAME}\"")
  546. set(HAVE_WAYLAND_SHARED TRUE)
  547. else()
  548. list(APPEND SDL_EXTRA_LIBS ${PKG_WAYLAND_LIBRARIES})
  549. endif()
  550. if(SDL_WAYLAND_LIBDECOR)
  551. pkg_check_modules(PKG_LIBDECOR libdecor-0)
  552. if(PKG_LIBDECOR_FOUND)
  553. set(HAVE_WAYLAND_LIBDECOR TRUE)
  554. set(HAVE_LIBDECOR_H 1)
  555. target_link_directories(sdl-build-options INTERFACE "${PKG_LIBDECOR_LIBRARY_DIRS}")
  556. target_include_directories(sdl-build-options INTERFACE "${PKG_LIBDECOR_INCLUDE_DIRS}")
  557. if(SDL_WAYLAND_LIBDECOR_SHARED AND NOT HAVE_SDL_LOADSO)
  558. message_warn("You must have SDL_LoadObject() support for dynamic libdecor loading")
  559. endif()
  560. FindLibraryAndSONAME(decor-0 LIBDIRS ${PKG_LIBDECOR_LIBRARY_DIRS})
  561. if(SDL_WAYLAND_LIBDECOR_SHARED AND DECOR_0_LIB AND HAVE_SDL_LOADSO)
  562. set(HAVE_WAYLAND_LIBDECOR_SHARED TRUE)
  563. set(SDL_VIDEO_DRIVER_WAYLAND_DYNAMIC_LIBDECOR "\"${DECOR_0_LIB_SONAME}\"")
  564. else()
  565. list(APPEND SDL_EXTRA_LIBS ${PKG_LIBDECOR_LIBRARIES})
  566. endif()
  567. endif()
  568. endif()
  569. set(SDL_VIDEO_DRIVER_WAYLAND 1)
  570. endif()
  571. endif()
  572. endmacro()
  573. # Requires:
  574. # - n/a
  575. #
  576. macro(CheckCOCOA)
  577. if(SDL_COCOA)
  578. if(APPLE) # Apple always has Cocoa.
  579. set(HAVE_COCOA TRUE)
  580. endif()
  581. if(HAVE_COCOA)
  582. file(GLOB COCOA_SOURCES ${SDL3_SOURCE_DIR}/src/video/cocoa/*.m)
  583. list(APPEND SOURCE_FILES ${COCOA_SOURCES})
  584. set(SDL_VIDEO_DRIVER_COCOA 1)
  585. set(HAVE_SDL_VIDEO TRUE)
  586. endif()
  587. endif()
  588. endmacro()
  589. # Requires:
  590. # - n/a
  591. macro(CheckVivante)
  592. if(SDL_VIVANTE)
  593. check_c_source_compiles("
  594. #include <gc_vdk.h>
  595. int main(int argc, char** argv) { return 0; }" HAVE_VIVANTE_VDK)
  596. check_c_source_compiles("
  597. #define LINUX
  598. #define EGL_API_FB
  599. #include <EGL/eglvivante.h>
  600. int main(int argc, char** argv) { return 0; }" HAVE_VIVANTE_EGL_FB)
  601. if(HAVE_VIVANTE_VDK OR HAVE_VIVANTE_EGL_FB)
  602. set(HAVE_VIVANTE TRUE)
  603. set(HAVE_SDL_VIDEO TRUE)
  604. file(GLOB VIVANTE_SOURCES ${SDL3_SOURCE_DIR}/src/video/vivante/*.c)
  605. list(APPEND SOURCE_FILES ${VIVANTE_SOURCES})
  606. set(SDL_VIDEO_DRIVER_VIVANTE 1)
  607. if(HAVE_VIVANTE_VDK)
  608. set(SDL_VIDEO_DRIVER_VIVANTE_VDK 1)
  609. find_library(VIVANTE_LIBRARY REQUIRED NAMES VIVANTE vivante drm_vivante)
  610. find_library(VIVANTE_VDK_LIBRARY VDK REQUIRED)
  611. list(APPEND SDL_EXTRA_LIBS ${VIVANTE_LIBRARY} ${VIVANTE_VDK_LIBRARY})
  612. else()
  613. list(APPEND SDL_PC_CFLAGS -DLINUX -DEGL_API_FB)
  614. list(APPEND SDL_EXTRA_LIBS EGL)
  615. endif(HAVE_VIVANTE_VDK)
  616. endif()
  617. endif()
  618. endmacro()
  619. # Requires:
  620. # - nada
  621. macro(CheckGLX)
  622. if(SDL_OPENGL)
  623. check_c_source_compiles("
  624. #include <GL/glx.h>
  625. int main(int argc, char** argv) { return 0; }" HAVE_OPENGL_GLX)
  626. if(HAVE_OPENGL_GLX AND NOT HAVE_ROCKCHIP)
  627. set(SDL_VIDEO_OPENGL_GLX 1)
  628. endif()
  629. endif()
  630. endmacro()
  631. # Requires:
  632. # - PkgCheckModules
  633. macro(CheckEGL)
  634. if (SDL_OPENGL OR SDL_OPENGLES)
  635. pkg_check_modules(EGL egl)
  636. set(CMAKE_REQUIRED_DEFINITIONS "${CMAKE_REQUIRED_DEFINITIONS} ${EGL_CFLAGS}")
  637. check_c_source_compiles("
  638. #define EGL_API_FB
  639. #define MESA_EGL_NO_X11_HEADERS
  640. #define EGL_NO_X11
  641. #include <EGL/egl.h>
  642. #include <EGL/eglext.h>
  643. int main (int argc, char** argv) { return 0; }" HAVE_OPENGL_EGL)
  644. if(HAVE_OPENGL_EGL)
  645. set(SDL_VIDEO_OPENGL_EGL 1)
  646. endif()
  647. endif()
  648. endmacro()
  649. # Requires:
  650. # - nada
  651. macro(CheckOpenGL)
  652. if(SDL_OPENGL)
  653. check_c_source_compiles("
  654. #include <GL/gl.h>
  655. #include <GL/glext.h>
  656. int main(int argc, char** argv) { return 0; }" HAVE_OPENGL)
  657. if(HAVE_OPENGL)
  658. set(SDL_VIDEO_OPENGL 1)
  659. set(SDL_VIDEO_RENDER_OGL 1)
  660. endif()
  661. endif()
  662. endmacro()
  663. # Requires:
  664. # - nada
  665. macro(CheckOpenGLES)
  666. if(SDL_OPENGLES)
  667. check_c_source_compiles("
  668. #include <GLES/gl.h>
  669. #include <GLES/glext.h>
  670. int main (int argc, char** argv) { return 0; }" HAVE_OPENGLES_V1)
  671. if(HAVE_OPENGLES_V1)
  672. set(HAVE_OPENGLES TRUE)
  673. set(SDL_VIDEO_OPENGL_ES 1)
  674. endif()
  675. check_c_source_compiles("
  676. #include <GLES2/gl2.h>
  677. #include <GLES2/gl2ext.h>
  678. int main (int argc, char** argv) { return 0; }" HAVE_OPENGLES_V2)
  679. if(HAVE_OPENGLES_V2)
  680. set(HAVE_OPENGLES TRUE)
  681. set(SDL_VIDEO_OPENGL_ES2 1)
  682. set(SDL_VIDEO_RENDER_OGL_ES2 1)
  683. endif()
  684. endif()
  685. endmacro()
  686. # Requires:
  687. # - nada
  688. # Optional:
  689. # - THREADS opt
  690. # Sets:
  691. # PTHREAD_CFLAGS
  692. # PTHREAD_LIBS
  693. macro(CheckPTHREAD)
  694. cmake_push_check_state()
  695. if(SDL_THREADS AND SDL_PTHREADS)
  696. if(ANDROID)
  697. # the android libc provides built-in support for pthreads, so no
  698. # additional linking or compile flags are necessary
  699. elseif(LINUX)
  700. set(PTHREAD_CFLAGS "-D_REENTRANT")
  701. set(PTHREAD_LDFLAGS "-pthread")
  702. elseif(BSDI)
  703. set(PTHREAD_CFLAGS "-D_REENTRANT -D_THREAD_SAFE")
  704. set(PTHREAD_LDFLAGS "")
  705. elseif(DARWIN)
  706. set(PTHREAD_CFLAGS "-D_THREAD_SAFE")
  707. # causes Carbon.p complaints?
  708. # set(PTHREAD_CFLAGS "-D_REENTRANT -D_THREAD_SAFE")
  709. set(PTHREAD_LDFLAGS "")
  710. elseif(FREEBSD)
  711. set(PTHREAD_CFLAGS "-D_REENTRANT -D_THREAD_SAFE")
  712. set(PTHREAD_LDFLAGS "-pthread")
  713. elseif(NETBSD)
  714. set(PTHREAD_CFLAGS "-D_REENTRANT -D_THREAD_SAFE")
  715. set(PTHREAD_LDFLAGS "-lpthread")
  716. elseif(OPENBSD)
  717. set(PTHREAD_CFLAGS "-D_REENTRANT")
  718. set(PTHREAD_LDFLAGS "-lpthread")
  719. elseif(SOLARIS)
  720. set(PTHREAD_CFLAGS "-D_REENTRANT")
  721. set(PTHREAD_LDFLAGS "-pthread -lposix4")
  722. elseif(SYSV5)
  723. set(PTHREAD_CFLAGS "-D_REENTRANT -Kthread")
  724. set(PTHREAD_LDFLAGS "")
  725. elseif(AIX)
  726. set(PTHREAD_CFLAGS "-D_REENTRANT -mthreads")
  727. set(PTHREAD_LDFLAGS "-pthread")
  728. elseif(HPUX)
  729. set(PTHREAD_CFLAGS "-D_REENTRANT")
  730. set(PTHREAD_LDFLAGS "-L/usr/lib -pthread")
  731. elseif(HAIKU)
  732. set(PTHREAD_CFLAGS "-D_REENTRANT")
  733. set(PTHREAD_LDFLAGS "")
  734. elseif(EMSCRIPTEN)
  735. set(PTHREAD_CFLAGS "-D_REENTRANT -pthread")
  736. set(PTHREAD_LDFLAGS "-pthread")
  737. else()
  738. set(PTHREAD_CFLAGS "-D_REENTRANT")
  739. set(PTHREAD_LDFLAGS "-lpthread")
  740. endif()
  741. # Run some tests
  742. set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${PTHREAD_CFLAGS} ${PTHREAD_LDFLAGS}")
  743. check_c_source_compiles("
  744. #include <pthread.h>
  745. int main(int argc, char** argv) {
  746. pthread_attr_t type;
  747. pthread_attr_init(&type);
  748. return 0;
  749. }" HAVE_PTHREADS)
  750. if(HAVE_PTHREADS)
  751. set(SDL_THREAD_PTHREAD 1)
  752. target_compile_options(sdl-build-options INTERFACE ${PTHREAD_CFLAGS})
  753. list(APPEND SDL_EXTRA_LDFLAGS ${PTHREAD_LDFLAGS})
  754. list(APPEND SDL_PC_CFLAGS ${PTHREAD_CFLAGS})
  755. check_c_source_compiles("
  756. #define _GNU_SOURCE 1
  757. #include <pthread.h>
  758. int main(int argc, char **argv) {
  759. pthread_mutexattr_t attr;
  760. pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
  761. return 0;
  762. }" HAVE_RECURSIVE_MUTEXES)
  763. if(HAVE_RECURSIVE_MUTEXES)
  764. set(SDL_THREAD_PTHREAD_RECURSIVE_MUTEX 1)
  765. else()
  766. check_c_source_compiles("
  767. #define _GNU_SOURCE 1
  768. #include <pthread.h>
  769. int main(int argc, char **argv) {
  770. pthread_mutexattr_t attr;
  771. pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE_NP);
  772. return 0;
  773. }" HAVE_RECURSIVE_MUTEXES_NP)
  774. if(HAVE_RECURSIVE_MUTEXES_NP)
  775. set(SDL_THREAD_PTHREAD_RECURSIVE_MUTEX_NP 1)
  776. endif()
  777. endif()
  778. if(SDL_PTHREADS_SEM)
  779. check_c_source_compiles("#include <pthread.h>
  780. #include <semaphore.h>
  781. int main(int argc, char **argv) { return 0; }" HAVE_PTHREADS_SEM)
  782. if(HAVE_PTHREADS_SEM)
  783. check_c_source_compiles("
  784. #include <pthread.h>
  785. #include <semaphore.h>
  786. int main(int argc, char **argv) {
  787. sem_timedwait(NULL, NULL);
  788. return 0;
  789. }" HAVE_SEM_TIMEDWAIT)
  790. endif()
  791. endif()
  792. check_include_file(pthread.h HAVE_PTHREAD_H)
  793. check_include_file(pthread_np.h HAVE_PTHREAD_NP_H)
  794. if (HAVE_PTHREAD_H)
  795. check_c_source_compiles("
  796. #define _GNU_SOURCE 1
  797. #include <pthread.h>
  798. int main(int argc, char **argv) {
  799. pthread_setname_np(pthread_self(), \"\");
  800. return 0;
  801. }" HAVE_PTHREAD_SETNAME_NP)
  802. if (HAVE_PTHREAD_NP_H)
  803. check_symbol_exists(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
  804. endif()
  805. endif()
  806. set(SOURCE_FILES ${SOURCE_FILES}
  807. ${SDL3_SOURCE_DIR}/src/thread/pthread/SDL_systhread.c
  808. ${SDL3_SOURCE_DIR}/src/thread/pthread/SDL_sysmutex.c # Can be faked, if necessary
  809. ${SDL3_SOURCE_DIR}/src/thread/pthread/SDL_syscond.c # Can be faked, if necessary
  810. ${SDL3_SOURCE_DIR}/src/thread/pthread/SDL_systls.c
  811. )
  812. if(HAVE_PTHREADS_SEM)
  813. set(SOURCE_FILES ${SOURCE_FILES}
  814. ${SDL3_SOURCE_DIR}/src/thread/pthread/SDL_syssem.c)
  815. else()
  816. set(SOURCE_FILES ${SOURCE_FILES}
  817. ${SDL3_SOURCE_DIR}/src/thread/generic/SDL_syssem.c)
  818. endif()
  819. set(HAVE_SDL_THREADS TRUE)
  820. endif()
  821. endif()
  822. cmake_pop_check_state()
  823. endmacro()
  824. # Requires
  825. # - nada
  826. # Optional:
  827. # Sets:
  828. # USB_LIBS
  829. # USB_CFLAGS
  830. macro(CheckUSBHID)
  831. cmake_push_check_state()
  832. check_library_exists(usbhid hid_init "" LIBUSBHID)
  833. if(LIBUSBHID)
  834. check_include_file(usbhid.h HAVE_USBHID_H)
  835. if(HAVE_USBHID_H)
  836. set(USB_CFLAGS "-DHAVE_USBHID_H")
  837. endif()
  838. check_include_file(libusbhid.h HAVE_LIBUSBHID_H)
  839. if(HAVE_LIBUSBHID_H)
  840. set(USB_CFLAGS "${USB_CFLAGS} -DHAVE_LIBUSBHID_H")
  841. endif()
  842. set(USB_LIBS ${USB_LIBS} usbhid)
  843. else()
  844. check_include_file(usb.h HAVE_USB_H)
  845. if(HAVE_USB_H)
  846. set(USB_CFLAGS "-DHAVE_USB_H")
  847. endif()
  848. check_include_file(libusb.h HAVE_LIBUSB_H)
  849. if(HAVE_LIBUSB_H)
  850. set(USB_CFLAGS "${USB_CFLAGS} -DHAVE_LIBUSB_H")
  851. endif()
  852. check_library_exists(usb hid_init "" LIBUSB)
  853. if(LIBUSB)
  854. list(APPEND USB_LIBS usb)
  855. endif()
  856. endif()
  857. set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${USB_CFLAGS}")
  858. list(APPEND CMAKE_REQUIRED_LIBRARIES ${USB_LIBS})
  859. check_c_source_compiles("
  860. #include <sys/types.h>
  861. #if defined(HAVE_USB_H)
  862. #include <usb.h>
  863. #endif
  864. #ifdef __DragonFly__
  865. # include <bus/u4b/usb.h>
  866. # include <bus/u4b/usbhid.h>
  867. #else
  868. # include <dev/usb/usb.h>
  869. # include <dev/usb/usbhid.h>
  870. #endif
  871. #if defined(HAVE_USBHID_H)
  872. #include <usbhid.h>
  873. #elif defined(HAVE_LIBUSB_H)
  874. #include <libusb.h>
  875. #elif defined(HAVE_LIBUSBHID_H)
  876. #include <libusbhid.h>
  877. #endif
  878. int main(int argc, char **argv) {
  879. struct report_desc *repdesc;
  880. struct usb_ctl_report *repbuf;
  881. hid_kind_t hidkind;
  882. return 0;
  883. }" HAVE_USBHID)
  884. if(HAVE_USBHID)
  885. check_c_source_compiles("
  886. #include <sys/types.h>
  887. #if defined(HAVE_USB_H)
  888. #include <usb.h>
  889. #endif
  890. #ifdef __DragonFly__
  891. # include <bus/u4b/usb.h>
  892. # include <bus/u4b/usbhid.h>
  893. #else
  894. # include <dev/usb/usb.h>
  895. # include <dev/usb/usbhid.h>
  896. #endif
  897. #if defined(HAVE_USBHID_H)
  898. #include <usbhid.h>
  899. #elif defined(HAVE_LIBUSB_H)
  900. #include <libusb.h>
  901. #elif defined(HAVE_LIBUSBHID_H)
  902. #include <libusbhid.h>
  903. #endif
  904. int main(int argc, char** argv) {
  905. struct usb_ctl_report buf;
  906. if (buf.ucr_data) { }
  907. return 0;
  908. }" HAVE_USBHID_UCR_DATA)
  909. if(HAVE_USBHID_UCR_DATA)
  910. set(USB_CFLAGS "${USB_CFLAGS} -DUSBHID_UCR_DATA")
  911. endif()
  912. check_c_source_compiles("
  913. #include <sys/types.h>
  914. #if defined(HAVE_USB_H)
  915. #include <usb.h>
  916. #endif
  917. #ifdef __DragonFly__
  918. #include <bus/u4b/usb.h>
  919. #include <bus/u4b/usbhid.h>
  920. #else
  921. #include <dev/usb/usb.h>
  922. #include <dev/usb/usbhid.h>
  923. #endif
  924. #if defined(HAVE_USBHID_H)
  925. #include <usbhid.h>
  926. #elif defined(HAVE_LIBUSB_H)
  927. #include <libusb.h>
  928. #elif defined(HAVE_LIBUSBHID_H)
  929. #include <libusbhid.h>
  930. #endif
  931. int main(int argc, char **argv) {
  932. report_desc_t d;
  933. hid_start_parse(d, 1, 1);
  934. return 0;
  935. }" HAVE_USBHID_NEW)
  936. if(HAVE_USBHID_NEW)
  937. set(USB_CFLAGS "${USB_CFLAGS} -DUSBHID_NEW")
  938. endif()
  939. check_c_source_compiles("
  940. #include <machine/joystick.h>
  941. int main(int argc, char** argv) {
  942. struct joystick t;
  943. return 0;
  944. }" HAVE_MACHINE_JOYSTICK)
  945. if(HAVE_MACHINE_JOYSTICK)
  946. set(SDL_HAVE_MACHINE_JOYSTICK_H 1)
  947. endif()
  948. set(SDL_JOYSTICK_USBHID 1)
  949. file(GLOB BSD_JOYSTICK_SOURCES ${SDL3_SOURCE_DIR}/src/joystick/bsd/*.c)
  950. list(APPEND SOURCE_FILES ${BSD_JOYSTICK_SOURCES})
  951. target_compile_options(sdl-build-options INTERFACE ${USB_CFLAGS})
  952. list(APPEND SDL_EXTRA_LIBS ${USB_LIBS})
  953. set(HAVE_SDL_JOYSTICK TRUE)
  954. endif()
  955. cmake_pop_check_state()
  956. endmacro()
  957. # Check for HIDAPI support
  958. macro(CheckHIDAPI)
  959. set(HAVE_HIDAPI TRUE)
  960. if(SDL_HIDAPI)
  961. if(SDL_HIDAPI_LIBUSB)
  962. set(HAVE_LIBUSB FALSE)
  963. pkg_check_modules(PKG_LIBUSB libusb-1.0)
  964. if(PKG_LIBUSB_FOUND)
  965. check_include_file(libusb.h HAVE_LIBUSB_H ${PKG_LIBUSB_CFLAGS})
  966. if(HAVE_LIBUSB_H)
  967. set(HAVE_LIBUSB TRUE)
  968. target_compile_options(sdl-build-options INTERFACE ${PKG_LIBUSB_CFLAGS})
  969. if(HIDAPI_ONLY_LIBUSB)
  970. list(APPEND SDL_EXTRA_LIBS ${PKG_LIBUSB_LIBRARIES})
  971. else()
  972. # libusb is loaded dynamically, so don't add it to SDL_EXTRA_LIBS
  973. FindLibraryAndSONAME("usb-1.0" LIBDIRS ${PKG_LIBUSB_LIBRARY_DIRS})
  974. if(USB_1.0_LIB)
  975. set(SDL_LIBUSB_DYNAMIC "\"${USB_1.0_LIB_SONAME}\"")
  976. endif()
  977. endif()
  978. endif()
  979. endif()
  980. if(HIDAPI_ONLY_LIBUSB AND NOT HAVE_LIBUSB)
  981. set(HAVE_HIDAPI FALSE)
  982. endif()
  983. set(HAVE_HIDAPI_LIBUSB ${HAVE_LIBUSB})
  984. endif()
  985. if(HAVE_HIDAPI)
  986. if(ANDROID)
  987. list(APPEND SOURCE_FILES ${SDL3_SOURCE_DIR}/src/hidapi/android/hid.cpp)
  988. endif()
  989. if(IOS OR TVOS)
  990. list(APPEND SOURCE_FILES ${SDL3_SOURCE_DIR}/src/hidapi/ios/hid.m)
  991. set(SDL_FRAMEWORK_COREBLUETOOTH 1)
  992. endif()
  993. set(HAVE_SDL_HIDAPI TRUE)
  994. if(SDL_JOYSTICK AND SDL_HIDAPI_JOYSTICK)
  995. set(SDL_JOYSTICK_HIDAPI 1)
  996. set(HAVE_SDL_JOYSTICK TRUE)
  997. set(HAVE_HIDAPI_JOYSTICK TRUE)
  998. file(GLOB HIDAPI_JOYSTICK_SOURCES ${SDL3_SOURCE_DIR}/src/joystick/hidapi/*.c)
  999. list(APPEND SOURCE_FILES ${HIDAPI_JOYSTICK_SOURCES})
  1000. endif()
  1001. else()
  1002. set(SDL_HIDAPI_DISABLED 1)
  1003. endif()
  1004. else()
  1005. set(SDL_HIDAPI_DISABLED 1)
  1006. endif()
  1007. endmacro()
  1008. # Requires:
  1009. # - n/a
  1010. macro(CheckRPI)
  1011. if(SDL_RPI)
  1012. pkg_check_modules(VIDEO_RPI bcm_host brcmegl)
  1013. if (NOT VIDEO_RPI_FOUND)
  1014. set(VIDEO_RPI_INCLUDE_DIRS "/opt/vc/include" "/opt/vc/include/interface/vcos/pthreads" "/opt/vc/include/interface/vmcs_host/linux/" )
  1015. set(VIDEO_RPI_LIBRARY_DIRS "/opt/vc/lib" )
  1016. set(VIDEO_RPI_LIBRARIES bcm_host )
  1017. set(VIDEO_RPI_LDFLAGS "-Wl,-rpath,/opt/vc/lib")
  1018. endif()
  1019. listtostr(VIDEO_RPI_INCLUDE_DIRS VIDEO_RPI_INCLUDE_FLAGS "-I")
  1020. listtostr(VIDEO_RPI_LIBRARY_DIRS VIDEO_RPI_LIBRARY_FLAGS "-L")
  1021. cmake_push_check_state()
  1022. set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${VIDEO_RPI_INCLUDE_FLAGS} ${VIDEO_RPI_LIBRARY_FLAGS}")
  1023. list(APPEND CMAKE_REQUIRED_LIBRARIES ${VIDEO_RPI_LIBRARIES})
  1024. check_c_source_compiles("
  1025. #include <bcm_host.h>
  1026. #include <EGL/eglplatform.h>
  1027. int main(int argc, char **argv) {
  1028. EGL_DISPMANX_WINDOW_T window;
  1029. bcm_host_init();
  1030. }" HAVE_RPI)
  1031. cmake_pop_check_state()
  1032. if(SDL_VIDEO AND HAVE_RPI)
  1033. set(HAVE_SDL_VIDEO TRUE)
  1034. set(SDL_VIDEO_DRIVER_RPI 1)
  1035. file(GLOB VIDEO_RPI_SOURCES ${SDL3_SOURCE_DIR}/src/video/raspberry/*.c)
  1036. list(APPEND SOURCE_FILES ${VIDEO_RPI_SOURCES})
  1037. list(APPEND SDL_EXTRA_LIBS ${VIDEO_RPI_LIBRARIES})
  1038. target_compile_options(sdl-build-options INTERFACE ${VIDEO_RPI_INCLUDE_FLAGS} ${VIDEO_RPI_LIBRARY_FLAGS})
  1039. list(APPEND SDL_EXTRA_LDFLAGS ${VIDEO_RPI_LDFLAGS})
  1040. endif()
  1041. endif()
  1042. endmacro()
  1043. # Requires:
  1044. # - n/a
  1045. macro(CheckROCKCHIP)
  1046. if(SDL_ROCKCHIP)
  1047. pkg_check_modules(VIDEO_ROCKCHIP mali)
  1048. if (VIDEO_ROCKCHIP_FOUND)
  1049. set(HAVE_ROCKCHIP TRUE)
  1050. endif()
  1051. if(SDL_VIDEO AND HAVE_ROCKCHIP)
  1052. set(HAVE_SDL_VIDEO TRUE)
  1053. set(SDL_VIDEO_DRIVER_ROCKCHIP 1)
  1054. endif()
  1055. endif()
  1056. endmacro()
  1057. # Requires:
  1058. # - EGL
  1059. # - PkgCheckModules
  1060. # Optional:
  1061. # - SDL_KMSDRM_SHARED opt
  1062. # - HAVE_SDL_LOADSO opt
  1063. macro(CheckKMSDRM)
  1064. if(SDL_KMSDRM)
  1065. pkg_check_modules(PKG_KMSDRM libdrm gbm egl)
  1066. if(PKG_KMSDRM_FOUND AND HAVE_OPENGL_EGL)
  1067. target_link_directories(sdl-build-options INTERFACE ${PKG_KMSDRM_LIBRARY_DIRS})
  1068. target_include_directories(sdl-build-options INTERFACE "${PKG_KMSDRM_INCLUDE_DIRS}")
  1069. set(HAVE_KMSDRM TRUE)
  1070. set(HAVE_SDL_VIDEO TRUE)
  1071. file(GLOB KMSDRM_SOURCES ${SDL3_SOURCE_DIR}/src/video/kmsdrm/*.c)
  1072. list(APPEND SOURCE_FILES ${KMSDRM_SOURCES})
  1073. target_compile_options(sdl-build-options INTERFACE ${PKG_KMSDRM_CFLAGS})
  1074. set(SDL_VIDEO_DRIVER_KMSDRM 1)
  1075. if(SDL_KMSDRM_SHARED AND NOT HAVE_SDL_LOADSO)
  1076. message_warn("You must have SDL_LoadObject() support for dynamic KMS/DRM loading")
  1077. endif()
  1078. if(SDL_KMSDRM_SHARED AND HAVE_SDL_LOADSO)
  1079. FindLibraryAndSONAME(drm LIBDIRS ${PKG_KMSDRM_LIBRARY_DIRS})
  1080. FindLibraryAndSONAME(gbm LIBDIRS ${PKG_KMSDRM_LIBRARY_DIRS})
  1081. set(SDL_VIDEO_DRIVER_KMSDRM_DYNAMIC "\"${DRM_LIB_SONAME}\"")
  1082. set(SDL_VIDEO_DRIVER_KMSDRM_DYNAMIC_GBM "\"${GBM_LIB_SONAME}\"")
  1083. set(HAVE_KMSDRM_SHARED TRUE)
  1084. else()
  1085. list(APPEND SDL_EXTRA_LIBS ${PKG_KMSDRM_LIBRARIES})
  1086. endif()
  1087. endif()
  1088. endif()
  1089. endmacro()
  1090. macro(CheckLibUDev)
  1091. if(SDL_LIBUDEV)
  1092. check_include_file("libudev.h" have_libudev_header)
  1093. if(have_libudev_header)
  1094. set(HAVE_LIBUDEV_H TRUE)
  1095. FindLibraryAndSONAME(udev)
  1096. if(UDEV_LIB_SONAME)
  1097. set(SDL_UDEV_DYNAMIC "\"${UDEV_LIB_SONAME}\"")
  1098. endif()
  1099. endif()
  1100. endif()
  1101. endmacro()